reserve y for set;
reserve x,a,b,c for Real;
reserve n for Element of NAT;
reserve Z for open Subset of REAL;
reserve f,f1,f2 for PartFunc of REAL,REAL;

theorem
  Z c= dom (ln*(f1/f2)) & (for x st x in Z holds f1.x=x-a & f1.x >0 & f2
  .x=x+a & f2.x >0) implies ln*(f1/f2) is_differentiable_on Z & for x st x in Z
  holds ((ln*(f1/f2))`|Z).x = (2*a)/(x^2-a^2)
proof
  assume that
A1: Z c= dom (ln*(f1/f2)) and
A2: for x st x in Z holds f1.x=x-a & f1.x >0 & f2.x=x+a & f2.x >0;
A3: for x st x in Z holds f2.x = 1*x+a by A2;
  for y being object st y in Z holds y in dom (f1/f2) by A1,FUNCT_1:11;
  then Z c= dom (f1/f2) by TARSKI:def 3;
  then
A4: Z c= dom f1 /\ (dom f2 \ f2"{0}) by RFUNCT_1:def 1;
  then
A5: Z c= dom f1 by XBOOLE_1:18;
A6: Z c= dom f2 by A4,XBOOLE_1:1;
  then
A7: f2 is_differentiable_on Z by A3,FDIFF_1:23;
A8: for x st x in Z holds f1.x = 1*x+-a
  proof
    let x;
A9: 1*x+-a=1*x-a;
    assume x in Z;
    hence thesis by A2,A9;
  end;
  then
A10: f1 is_differentiable_on Z by A5,FDIFF_1:23;
  for x st x in Z holds f2.x <> 0 by A2;
  then
A11: f1/f2 is_differentiable_on Z by A10,A7,FDIFF_2:21;
A12: for x st x in Z holds ((f1/f2)`|Z).x = (2*a)/(x+a)^2
  proof
    let x;
    assume
A13: x in Z;
    then
A14: f2.x <>0 by A2;
A15: f1.x=x-a & f2.x=x+a by A2,A13;
    f1 is_differentiable_in x & f2 is_differentiable_in x by A10,A7,A13,
FDIFF_1:9;
    then diff(f1/f2,x) =(diff(f1,x) * f2.x - diff(f2,x) * f1.x)/(f2.x)^2 by A14
,FDIFF_2:14
      .=((f1`|Z).x * f2.x-diff(f2,x) * f1.x)/(f2.x)^2 by A10,A13,FDIFF_1:def 7
      .= ((f1`|Z).x * f2.x-(f2`|Z).x * f1.x)/(f2.x)^2 by A7,A13,FDIFF_1:def 7
      .=(1* f2.x-(f2`|Z).x * f1.x)/(f2.x)^2 by A5,A8,A13,FDIFF_1:23
      .=(1* f2.x-1* f1.x)/(f2.x)^2 by A6,A3,A13,FDIFF_1:23
      .=(2*a)/(x+a)^2 by A15;
    hence thesis by A11,A13,FDIFF_1:def 7;
  end;
A16: for x st x in Z holds (f1/f2).x >0
  proof
    let x;
    assume
A17: x in Z;
    then x in dom (f1/f2) by A1,FUNCT_1:11;
    then
A18: (f1/f2).x=f1.x * (f2.x)" by RFUNCT_1:def 1
      .=f1.x / f2.x by XCMPLX_0:def 9;
    f1.x >0 & f2.x >0 by A2,A17;
    hence thesis by A18,XREAL_1:139;
  end;
A19: for x st x in Z holds ln*(f1/f2) is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then f1/f2 is_differentiable_in x & (f1/f2).x >0 by A11,A16,FDIFF_1:9;
    hence thesis by TAYLOR_1:20;
  end;
  then
A20: ln*(f1/f2) is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((ln*(f1/f2))`|Z).x = (2*a)/(x^2-a^2)
  proof
    let x;
    assume
A21: x in Z;
    then
A22: f2.x=x+a & f2.x>0 by A2;
A23: f1.x=x-a & f2.x=x+a by A2,A21;
A24: x in dom (f1/f2) by A1,A21,FUNCT_1:11;
    (f1/f2) is_differentiable_in x & (f1/f2).x >0 by A11,A16,A21,FDIFF_1:9;
    then diff(ln*(f1/f2),x) =diff((f1/f2),x)/((f1/f2).x) by TAYLOR_1:20
      .=((f1/f2)`|Z).x/((f1/f2).x) by A11,A21,FDIFF_1:def 7
      .=((2*a)/(x+a)^2)/((f1/f2).x) by A12,A21
      .=((2*a)/(x+a)^2)/(f1.x * (f2.x)") by A24,RFUNCT_1:def 1
      .=((2*a)/((x+a)*(x+a)))/((x-a)/(x+a)) by A23,XCMPLX_0:def 9
      .=((2*a)/(x+a)/(x+a))/((x-a)/(x+a)) by XCMPLX_1:78
      .=((2*a)/(x+a))/((x-a)/(x+a))/(x+a) by XCMPLX_1:48
      .=(2*a)/(x-a)/(x+a) by A22,XCMPLX_1:55
      .=(2*a)/((x-a)*(x+a)) by XCMPLX_1:78
      .=(2*a)/(x^2-a^2);
    hence thesis by A20,A21,FDIFF_1:def 7;
  end;
  hence thesis by A1,A19,FDIFF_1:9;
end;
