
theorem Th23:
  for S being GraphUnionSet, G being GraphUnion of S holds
    (S is loopless iff G is loopless) &
    (S is edgeless iff G is edgeless) &
    (S is loopfull implies G is loopfull)
proof
  let S be GraphUnionSet, G be GraphUnion of S;
  :: loopless
  hereby
    assume A1: S is loopless;
    assume G is non loopless;
    then consider v being object such that
      A2: ex e being object st e DJoins v,v,G by GLIB_000:136;
    reconsider v as set by TARSKI:1;
    consider e being object such that
      A3: e DJoins v,v,G by A2;
    reconsider e as set by TARSKI:1;
    e in the_Edges_of G by A3, GLIB_000:def 14;
    then e in union the_Edges_of S by Def25;
    then consider E being set such that
      A4: e in E & E in the_Edges_of S by TARSKI:def 4;
    consider H being _Graph such that
      A5: H in S & E = the_Edges_of H by A4, Def15;
    H is Subgraph of G by A5, Th21;
    then e DJoins v,v,H by A3, A4, A5, GLIB_000:73;
    hence contradiction by A1, A5, GLIB_000:136;
  end;
  hereby
    assume A6: G is loopless;
    now
      let H be _Graph;
      assume  H in S;
      then H is Subgraph of G by Th21;
      hence H is loopless by A6;
    end;
    hence S is loopless;
  end;
  :: edgeless
  hereby
    assume A8: S is edgeless;
    the_Edges_of G = union the_Edges_of S by Def25;
    hence G is edgeless by A8;
  end;
  hereby
    assume A9: G is edgeless;
    now
      let H be _Graph;
      assume  H in S;
      then H is Subgraph of G by Th21;
      hence H is edgeless by A9;
    end;
    hence S is edgeless;
  end;
  :: loopfull
  hereby
    assume A11: S is loopfull;
    now
      let v be Vertex of G;
      v in the_Vertices_of G;
      then v in union the_Vertices_of S by Def25;
      then consider V being set such that
        A12: v in V & V in the_Vertices_of S by TARSKI:def 4;
      consider H being _Graph such that
        A13: H in S & V = the_Vertices_of H by A12, Def14;
      consider e being object such that
        A14: e DJoins v,v,H by A11, A12, A13, GLIB_012:1;
      take e;
      H is Subgraph of G by A13, Th21;
      hence e DJoins v,v,G by A14, GLIB_000:72;
    end;
    hence G is loopfull by GLIB_012:1;
  end;
end;
