
theorem
  for n being Element of NAT, T being connected admissible TermOrder of
  n, L being add-associative right_complementable right_zeroed commutative
  associative well-unital distributive Abelian almost_left_invertible non
  degenerated non empty doubleLoopStr, G being Subset of Polynom-Ring(n,L)
holds G is_Groebner_basis_wrt T implies (for g1,g2,h being Polynomial of n,L st
g1 in G & g2 in G & h is_a_normal_form_of S-Poly(g1,g2,T),PolyRedRel(G,T) holds
  h = 0_(n,L))
proof
  let n be Element of NAT, T be connected admissible TermOrder of n, L be
  add-associative right_complementable right_zeroed commutative associative
  well-unital distributive Abelian almost_left_invertible non degenerated non
  empty doubleLoopStr, G be Subset of Polynom-Ring(n,L);
  assume
A1: G is_Groebner_basis_wrt T;
  set R = PolyRedRel(G,T);
A2: 0_(n,L) = 0.Polynom-Ring(n,L) by POLYNOM1:def 11;
  per cases;
  suppose
    G = {};
    hence thesis;
  end;
  suppose
    G <> {};
    then reconsider G as non empty Subset of Polynom-Ring(n,L);
A3: R is locally-confluent by A1,GROEB_1:def 3;
    now
A4:   now
        assume not 0_(n,L) is_a_normal_form_wrt R;
        then consider b being object such that
A5:     [0_(n,L),b] in R by REWRITE1:def 5;
        consider f1,f2 being object such that
A6:     f1 in NonZero Polynom-Ring(n,L) and
        f2 in the carrier of Polynom-Ring(n,L) and
A7:     [0_(n,L),b] = [f1,f2] by A5,ZFMISC_1:def 2;
A8:     f1 = 0_(n,L) by A7,XTUPLE_0:1;
        not f1 in {0_(n,L)} by A2,A6,XBOOLE_0:def 5;
        hence contradiction by A8,TARSKI:def 1;
      end;
      let g1,g2,h being Polynomial of n,L;
      assume that
A9:   g1 in G & g2 in G and
A10:  h is_a_normal_form_of S-Poly(g1,g2,T),R;
      S-Poly(g1,g2,T) in G-Ideal by A9,Th18;
      then R reduces S-Poly(g1,g2,T),0_(n,L) by A3,GROEB_1:15;
      then
A11:  S-Poly(g1,g2,T),0_(n,L) are_convertible_wrt R by REWRITE1:25;
      R reduces S-Poly(g1,g2,T),h by A10,REWRITE1:def 6;
      then h,S-Poly(g1,g2,T) are_convertible_wrt R by REWRITE1:25;
      then
A12:  h,0_(n,L) are_convertible_wrt R by A11,REWRITE1:30;
      h is_a_normal_form_wrt R by A10,REWRITE1:def 6;
      hence h = 0_(n,L) by A3,A4,A12,REWRITE1:def 19;
    end;
    hence thesis;
  end;
end;
