reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;

theorem Th23:
  for N1,N2 being strict normal StableSubgroup of G ex N being
  strict normal StableSubgroup of G st the carrier of N = carr N1 * carr N2
proof
  let N1,N2 be strict normal StableSubgroup of G;
  set N19 = the multMagma of N1;
  set N29 = the multMagma of N2;
  reconsider N19,N29 as strict normal Subgroup of G by Lm6;
  set A = carr N19 * carr N29;
  set B = carr N19;
  set C = carr N29;
  carr N19 * carr N29 = carr N29 * carr N19 by GROUP_3:125;
  then consider H9 be strict Subgroup of G such that
A1: the carrier of H9 = A by GROUP_2:78;
A2: now
    let o be Element of O;
    let g be Element of G;
    assume g in A;
    then consider a,b be Element of G such that
A3: g = a * b and
A4: a in carr N1 and
A5: b in carr N2;
    a in N1 by A4,STRUCT_0:def 5;
    then (G^o).a in N1 by Lm9;
    then
A6: (G^o).a in carr N1 by STRUCT_0:def 5;
    b in N2 by A5,STRUCT_0:def 5;
    then (G^o).b in N2 by Lm9;
    then (G^o).b in carr N2 by STRUCT_0:def 5;
    then ((G^o).a) * ((G^o).b) in carr N1 * carr N2 by A6;
    hence (G^o).g in A by A3,GROUP_6:def 6;
  end;
A7: now
    let g be Element of G;
    assume g in A;
    then g in H9 by A1,STRUCT_0:def 5;
    then g" in H9 by GROUP_2:51;
    hence g" in A by A1,STRUCT_0:def 5;
  end;
  now
    let g1,g2 be Element of G;
    assume g1 in A & g2 in A;
    then g1 in H9 & g2 in H9 by A1,STRUCT_0:def 5;
    then g1 * g2 in H9 by GROUP_2:50;
    hence g1 * g2 in A by A1,STRUCT_0:def 5;
  end;
  then consider H be strict StableSubgroup of G such that
A8: the carrier of H = A by A1,A7,A2,Lm14;
  now
    let a be Element of G;
    thus a * H9 = a * N19 * C by A1,GROUP_2:29
      .= N19 * a * C by GROUP_3:117
      .= B * (a * N29) by GROUP_2:30
      .= B * (N29 * a) by GROUP_3:117
      .= H9 * a by A1,GROUP_2:31;
  end;
  then H9 is normal Subgroup of G by GROUP_3:117;
  then for H99 being strict Subgroup of G st H99 = the multMagma of H holds
  H99 is normal by A1,A8,GROUP_2:59;
  then H is normal;
  hence thesis by A8;
end;
