reserve x for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th23:
  for Kb,Cb being Subset of TOP-REAL 2 st Kb={q: -1=q`1 & -1<=q`2
& q`2<=1 or q`1=1 & -1<=q`2 & q`2<=1 or -1=q`2 & -1<=q`1 & q`1<=1 or 1=q`2 & -1
  <=q`1 & q`1<=1}& Cb={p2 where p2 is Point of TOP-REAL 2: |.p2.|=1} holds
  Sq_Circ.:Kb=Cb
proof
  let Kb,Cb be Subset of TOP-REAL 2;
  assume
A1: Kb={q: -1=q`1 & -1<=q`2 & q`2<=1 or q`1=1 & -1<=q`2 & q`2<=1 or -1=q
`2 & -1<=q`1 & q`1<=1 or 1=q`2 & -1<=q`1 & q`1<=1}& Cb={p2 where p2 is Point of
  TOP-REAL 2: |.p2.|=1};
  thus Sq_Circ.:Kb c= Cb
  proof
    let y be object;
    assume y in Sq_Circ.:Kb;
    then consider x being object such that
    x in dom Sq_Circ and
A2: x in Kb and
A3: y=Sq_Circ.x by FUNCT_1:def 6;
    consider q being Point of TOP-REAL 2 such that
A4: q=x and
A5: -1=q`1 & -1<=q`2 & q`2<=1 or q`1=1 & -1<=q`2 & q`2<=1 or -1=q`2 &
    - 1<=q`1 & q`1<=1 or 1=q`2 & -1<=q`1 & q`1<=1 by A1,A2;
    now
      per cases;
      case
        q=0.TOP-REAL 2;
        hence contradiction by A5,JGRAPH_2:3;
      end;
      case
A6:     q<>0.TOP-REAL 2 & (q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2<=-q `1);
A7:     (|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|)`1 = q`1/
sqrt(1+(q `2/q `1)^2) & (|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|)`2
        = q`2/sqrt(1+ (q `2/q`1)^2) by EUCLID:52;
A8:     1+(q`2)^2>0 by Lm1;
A9:     Sq_Circ.q=|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2 )]| by A6
,Def1;
        now
          per cases by A5;
          case
            -1=q`1 & -1<=q`2 & q`2<=1;
            then
            |.(|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|).|^2 =
((-1)/sqrt(1+(q`2/(-1))^2))^2+(q`2/sqrt(1+(q`2/(-1))^2))^2 by A7,JGRAPH_1:29
              .=(-1)^2/(sqrt(1+(q`2/(-1))^2))^2+(q`2/sqrt(1+(q`2/(-1))^2))^2
            by XCMPLX_1:76
              .=1/(sqrt(1+(-q`2)^2))^2+(q`2)^2/(sqrt(1+(-q`2)^2))^2 by
XCMPLX_1:76
              .=1/(1+(q`2)^2)+(q`2)^2/(sqrt(1+(q`2)^2))^2 by A8,SQUARE_1:def 2
              .=1/(1+(q`2)^2)+(q`2)^2/(1+(q`2)^2) by A8,SQUARE_1:def 2
              .=(1+(q`2)^2)/(1+(q`2)^2) by XCMPLX_1:62
              .=1 by A8,XCMPLX_1:60;
            then |.(|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|).|=1
            by SQUARE_1:18,22;
            hence ex p2 being Point of TOP-REAL 2 st p2=y & |.p2.|=1 by A3,A4
,A9;
          end;
          case
            q`1=1 & -1<=q`2 & q`2<=1;
            then
            |.(|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|).|^2 =
(1/sqrt(1+(q`2/(1))^2))^2+(q`2/sqrt(1+(q`2/(1))^2))^2 by A7,JGRAPH_1:29
              .=1^2/(sqrt(1+(q`2/(1))^2))^2+(q`2/sqrt(1+(q`2/(1))^2))^2 by
XCMPLX_1:76
              .=1/(sqrt(1+(q`2/(1))^2))^2+(q`2)^2/(sqrt(1+(q`2/(1))^2))^2 by
XCMPLX_1:76
              .=1/(1+(q`2)^2)+(q`2)^2/(sqrt(1+(q`2)^2))^2 by A8,SQUARE_1:def 2
              .=1/(1+(q`2)^2)+(q`2)^2/(1+(q`2)^2) by A8,SQUARE_1:def 2
              .=(1+(q`2)^2)/(1+(q`2)^2) by XCMPLX_1:62
              .=1 by A8,XCMPLX_1:60;
            then |.(|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|).|=1
            by SQUARE_1:18,22;
            hence ex p2 being Point of TOP-REAL 2 st p2=y & |.p2.|=1 by A3,A4
,A9;
          end;
          case
A10:        -1=q`2 & -1<=q`1 & q`1<=1;
            then -1<=q`1 & q`1>=1 or -1>=q`1 & 1>=q`1 by A6,XREAL_1:24;
            then
A11:        q`1=1 or q`1=-1 by A10,XXREAL_0:1;
            |.(|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|).|^2 =
((q`1)/sqrt(1+((-1)/(q`1))^2))^2+((-1)/sqrt(1+((-1)/(q`1))^2))^2 by A7,A10,
JGRAPH_1:29
              .=((q`1)/sqrt(1+((-1)/(q`1))^2))^2+(-1)^2/(sqrt(1+((-1)/(q`1))
            ^2))^2 by XCMPLX_1:76
              .=(q`1)^2/(sqrt(1+((-1)/(q`1))^2))^2+1/(sqrt(1+((-1)/(q`1))^2)
            )^2 by XCMPLX_1:76
              .=1/2+1/(sqrt(2))^2 by A11,SQUARE_1:def 2
              .=1/2+1/2 by SQUARE_1:def 2
              .=1;
            then |.(|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|).|=1
            by SQUARE_1:18,22;
            hence ex p2 being Point of TOP-REAL 2 st p2=y & |.p2.|=1 by A3,A4
,A9;
          end;
          case
A12:        1=q`2 & -1<=q`1 & q`1<=1;
            then 1<=q`1 & q`1>=-1 or 1>=q`1 & -1>=q`1 by A6,XREAL_1:25;
            then
A13:        q`1=1 or q`1=-1 by A12,XXREAL_0:1;
            |.(|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|).|^2 =
((q`1)/sqrt(1+((1)/(q`1))^2))^2+((1)/sqrt(1+((1)/(q`1))^2))^2 by A7,A12,
JGRAPH_1:29
              .=((q`1)/sqrt(1+((1)/(q`1))^2))^2+(1)^2/(sqrt(1+((1)/(q`1))^2)
            )^2 by XCMPLX_1:76
              .=1/(sqrt(1+1/1))^2+1/(sqrt(1+1/1))^2 by A13,XCMPLX_1:76
              .=1/2+1/(sqrt(2))^2 by SQUARE_1:def 2
              .=1/2+1/2 by SQUARE_1:def 2
              .=1;
            then |.(|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|).|=1
            by SQUARE_1:18,22;
            hence ex p2 being Point of TOP-REAL 2 st p2=y & |.p2.|=1 by A3,A4
,A9;
          end;
        end;
        hence ex p2 being Point of TOP-REAL 2 st p2=y & |.p2.|=1;
      end;
      case
A14:    q<>0.TOP-REAL 2 & not(q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2 <=-q`1);
A15:    (|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2)]|)`1 = q`1/
sqrt(1+(q `1/q `2)^2) & (|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2)]|)`2
        = q`2/sqrt(1+ (q `1/q`2)^2) by EUCLID:52;
A16:    1+(q`1)^2>0 by Lm1;
A17:    Sq_Circ.q=|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2 )]| by A14
,Def1;
        now
          per cases by A5;
          case
            -1=q`2 & -1<=q`1 & q`1<=1;
            then |.(|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2)]|).| ^2
=(q`1/sqrt(1+(q`1/(-1))^2))^2+((-1)/sqrt(1+(q`1/(-1))^2))^2 by A15,JGRAPH_1:29
              .=(-1)^2/(sqrt(1+(q`1/(-1))^2))^2+(q`1/sqrt(1+(q`1/(-1))^2))^2
            by XCMPLX_1:76
              .=1/(sqrt(1+(-q`1)^2))^2+(q`1)^2/(sqrt(1+(-q`1)^2))^2 by
XCMPLX_1:76
              .=1/(1+(q`1)^2)+(q`1)^2/(sqrt(1+(q`1)^2))^2 by A16,SQUARE_1:def 2
              .=1/(1+(q`1)^2)+(q`1)^2/(1+(q`1)^2) by A16,SQUARE_1:def 2
              .=(1+(q`1)^2)/(1+(q`1)^2) by XCMPLX_1:62
              .=1 by A16,XCMPLX_1:60;
            then |.(|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2)]|).|=1
            by SQUARE_1:18,22;
            hence ex p2 being Point of TOP-REAL 2 st p2=y & |.p2.|=1 by A3,A4
,A17;
          end;
          case
            q`2=1 & -1<=q`1 & q`1<=1;
            then |.(|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2)]|).| ^2
=((1)/sqrt(1+(q`1/(1))^2))^2+(q`1/sqrt(1+(q`1/(1))^2))^2 by A15,JGRAPH_1:29
              .=1^2/(sqrt(1+(q`1/(1))^2))^2+(q`1/sqrt(1+(q`1/(1))^2))^2 by
XCMPLX_1:76
              .=1/(sqrt(1+(q`1/(1))^2))^2+(q`1)^2/(sqrt(1+(q`1/(1))^2))^2 by
XCMPLX_1:76
              .=1/(1+(q`1)^2)+(q`1)^2/(sqrt(1+(q`1)^2))^2 by A16,SQUARE_1:def 2
              .=1/(1+(q`1)^2)+(q`1)^2/(1+(q`1)^2) by A16,SQUARE_1:def 2
              .=(1+(q`1)^2)/(1+(q`1)^2) by XCMPLX_1:62
              .=1 by A16,XCMPLX_1:60;
            then |.(|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2)]|).|=1
            by SQUARE_1:18,22;
            hence ex p2 being Point of TOP-REAL 2 st p2=y & |.p2.|=1 by A3,A4
,A17;
          end;
          case
            -1=q`1 & -1<=q`2 & q`2<=1;
            hence ex p2 being Point of TOP-REAL 2 st p2=y & |.p2.|=1 by A14;
          end;
          case
            1=q`1 & -1<=q`2 & q`2<=1;
            hence ex p2 being Point of TOP-REAL 2 st p2=y & |.p2.|=1 by A14;
          end;
        end;
        hence ex p2 being Point of TOP-REAL 2 st p2=y & |.p2.|=1;
      end;
    end;
    hence thesis by A1;
  end;
  let y be object;
  assume y in Cb;
  then consider p2 being Point of TOP-REAL 2 such that
A18: p2=y and
A19: |.p2.|=1 by A1;
  set q=p2;
  now
    per cases;
    case
      q=0.TOP-REAL 2;
      hence contradiction by A19,TOPRNS_1:23;
    end;
    case
A20:  q<>0.TOP-REAL 2 & (q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2<=-q`1 );
A21:  |.q.|^2=q`1^2+q`2^2 by JGRAPH_1:29;
      set px=|[q`1*sqrt(1+(q`2/q`1)^2),q`2*sqrt(1+(q`2/q`1)^2)]|;
A22:  px`1 = q`1*sqrt(1+(q`2/q`1)^2) by EUCLID:52;
A23:  sqrt(1+(q`2/q`1)^2)>0 by Lm1,SQUARE_1:25;
      then
A24:  q`2=q`2*sqrt(1+(q`2/q`1)^2)/(sqrt(1+(q`2/q`1)^2))by XCMPLX_1:89
        .=px`2/(sqrt(1+(q`2/q`1)^2)) by EUCLID:52;
A25:  px`2 = q`2*sqrt(1+(q`2/q`1)^2) by EUCLID:52;
      then
A26:  px`2/px`1=q`2/q`1 by A22,A23,XCMPLX_1:91;
      then
A27:  px`2/sqrt(1+(px`2/px`1)^2)=q`2 by A25,A23,XCMPLX_1:89;
      q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2*sqrt(1+(q`2/q`1)^2) <= (-q`1
      )*sqrt(1+(q`2/q`1)^2) by A20,A23,XREAL_1:64;
      then
A28:  q`2<=q`1 & (-q`1)*sqrt(1+(q`2/q`1)^2) <= q`2*sqrt(1+(q`2/q`1) ^2)
      or px`2>=px`1 & px`2<=-px`1 by A22,A25,A23,XREAL_1:64;
A29:  1+(px`2/px`1)^2>0 by Lm1;
      q`1=q`1*sqrt(1+(q`2/q`1)^2)/(sqrt(1+(q`2/q`1)^2))by A23,XCMPLX_1:89
        .=px`1/(sqrt(1+(q`2/q`1)^2)) by EUCLID:52;
      then (px`1)^2/(sqrt(1+(px`2/px`1)^2))^2+(px`2/sqrt(1+(px`2/px`1)^2)) ^2
      = 1 by A19,A26,A24,A21,XCMPLX_1:76;
      then
      (px`1)^2/(sqrt(1+(px`2/px`1)^2))^2+(px`2)^2/(sqrt(1+(px`2/px`1)^2))
      ^2=1 by XCMPLX_1:76;
      then (px`1)^2/(1+(px`2/px`1)^2)+(px`2)^2/(sqrt(1+(px`2/px`1)^2))^2=1 by
A29,SQUARE_1:def 2;
      then
      1 *(1+(px`2/px`1)^2)= (1+(px`2/px`1)^2)*((px`1)^2/(1+(px`2/px`1)^2)
      + (px`2)^2/(1+(px`2/px`1)^2)) by A29,SQUARE_1:def 2
        .= (px`1)^2/(1+(px`2/px`1)^2)*(1+(px`2/px`1)^2) +(px`2)^2/(1+(px`2/
      px`1)^2)*(1+(px`2/px`1)^2);
      then (px`1)^2+(px`2)^2/(1+(px`2/px`1)^2)*(1+(px`2/px`1)^2)=1 *(1+(px`2/
      px `1)^2) by A29,XCMPLX_1:87;
      then
A30:  (px`1)^2+(px`2)^2=1 *(1+(px`2/px`1)^2) by A29,XCMPLX_1:87
        .=1+(px`2)^2/(px`1)^2 by XCMPLX_1:76;
A31:  now
        assume that
A32:    px`1=0 and
A33:    px`2=0;
        q`2*sqrt(1+(q`2/q`1)^2)=0 by A33,EUCLID:52;
        then
A34:    q`2=0 by A23,XCMPLX_1:6;
        q`1*sqrt(1+(q`2/q`1)^2)=0 by A32,EUCLID:52;
        then q`1=0 by A23,XCMPLX_1:6;
        hence contradiction by A20,A34,EUCLID:53,54;
      end;
      then not px`1=0 by A22,A25,A23,A28,XREAL_1:64;
      then ((px`1)^2+((px`2)^2-1))*(px`1)^2=(px`2)^2 by A30,XCMPLX_1:6,87;
      then 0= ((px`1)^2-1)*((px`1)^2+(px`2)^2);
      then
A35:  (px`1)^2-1=0 or (px`1)^2+(px`2)^2=0 by XCMPLX_1:6;
      now
        per cases by A31,A35,COMPLEX1:1,SQUARE_1:41;
        case
          px`1=1;
          hence -1=px`1 & -1<=px`2 & px`2<=1 or px`1=1 & -1<=px`2 & px`2<=1 or
-1=px`2 & -1<=px`1 & px`1<=1 or 1=px`2 & -1<=px`1 & px`1<=1 by A22,A25,A23,A28,
XREAL_1:64;
        end;
        case
          px`1=-1;
          hence -1=px`1 & -1<=px`2 & px`2<=1 or px`1=1 & -1<=px`2 & px`2<=1 or
-1=px`2 & -1<=px`1 & px`1<=1 or 1=px`2 & -1<=px`1 & px`1<=1 by A22,A23,A28,
XREAL_1:64;
        end;
      end;
      then
A36:  dom Sq_Circ=the carrier of TOP-REAL 2 & px in Kb by A1,FUNCT_2:def 1;
      px`2<=px`1 & -px`1<=px`2 or px`2>=px`1 & px`2<=-px`1 by A22,A25,A23,A28,
XREAL_1:64;
      then
A37:  Sq_Circ.px=|[px`1/sqrt(1+(px`2/px`1)^2),px`2/sqrt(1+(px`2/px`1 )^2)
      ]| by A31,Def1,JGRAPH_2:3;
      px`1/sqrt(1+(px`2/px`1)^2)=q`1 by A22,A23,A26,XCMPLX_1:89;
      hence ex x being set st x in dom Sq_Circ & x in Kb & y=Sq_Circ.x by A18
,A37,A27,A36,EUCLID:53;
    end;
    case
A38:  q<>0.TOP-REAL 2 & not(q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2<=- q`1);
A39:  |.q.|^2=q`2^2+q`1^2 by JGRAPH_1:29;
      set px=|[q`1*sqrt(1+(q`1/q`2)^2),q`2*sqrt(1+(q`1/q`2)^2)]|;
A40:  sqrt(1+(q`1/q`2)^2)>0 by Lm1,SQUARE_1:25;
A41:  px`1 = q`1*sqrt(1+(q`1/q`2)^2) by EUCLID:52;
      then
A42:  q`1=px`1/(sqrt(1+(q`1/q`2)^2)) by A40,XCMPLX_1:89;
A43:  px`2 = q`2*sqrt(1+(q`1/q`2)^2) by EUCLID:52;
      then
A44:  px`1/px`2=q`1/q`2 by A41,A40,XCMPLX_1:91;
      then
A45:  px`1/sqrt(1+(px`1/px`2)^2)=q`1 by A41,A40,XCMPLX_1:89;
      q`1<=q`2 & -q`2<=q`1 or q`1>=q`2 & q`1<=-q`2 by A38,JGRAPH_2:13;
      then
      q`1<=q`2 & -q`2<=q`1 or q`1>=q`2 & q`1*sqrt(1+(q`1/q`2)^2) <= (-q`2
      )*sqrt(1+(q`1/q`2)^2) by A40,XREAL_1:64;
      then
A46:  q`1<=q`2 & (-q`2)*sqrt(1+(q`1/q`2)^2) <= q`1*sqrt(1+(q`1/q`2) ^2)
      or px`1>=px`2 & px`1<=-px`2 by A43,A41,A40,XREAL_1:64;
A47:  1+(px`1/px`2)^2>0 by Lm1;
      q`2=px`2/(sqrt(1+(q`1/q`2)^2)) by A43,A40,XCMPLX_1:89;
      then (px`2)^2/(sqrt(1+(px`1/px`2)^2))^2+(px`1/sqrt(1+(px`1/px`2)^2)) ^2
      = 1 by A19,A44,A42,A39,XCMPLX_1:76;
      then (px`2)^2/(sqrt(1+(px`1/px`2)^2))^2+(px`1)^2/(sqrt(1+(px`1/px`2)^2)
      ) ^2=1 by XCMPLX_1:76;
      then (px`2)^2/(1+(px`1/px`2)^2)+(px`1)^2/(sqrt(1+(px`1/px`2)^2))^2=1 by
A47,SQUARE_1:def 2;
      then 1 *(1+(px`1/px`2)^2) = (1+(px`1/px`2)^2)*( (px`2)^2/(1+(px`1/px`2)
      ^2) +(px`1)^2/(1+(px`1/px`2)^2)) by A47,SQUARE_1:def 2
        .= (px`2)^2/(1+(px`1/px`2)^2)*(1+(px`1/px`2)^2) +(px`1)^2/(1+(px`1/
      px`2)^2)*(1+(px`1/px`2)^2);
      then (px`2)^2+(px`1)^2/(1+(px`1/px`2)^2)*(1+(px`1/px`2)^2)=1 *(1+(px`1/
      px `2)^2) by A47,XCMPLX_1:87;
      then (px`2)^2+(px`1)^2=1 *(1+(px`1/px`2)^2) by A47,XCMPLX_1:87;
      then
A48:  (px`2)^2+(px`1)^2-1=(px`1)^2/(px`2)^2 by XCMPLX_1:76;
A49:  now
        assume that
A50:    px`2=0 and
        px`1=0;
        q`2=0 by A43,A40,A50,XCMPLX_1:6;
        hence contradiction by A38;
      end;
      then px`2<>0 by A43,A41,A40,A46,XREAL_1:64;
      then ((px`2)^2+((px`1)^2-1))*(px`2)^2=(px`1)^2 by A48,XCMPLX_1:6,87;
      then 0=((px`2)^2-1)*((px`2)^2+(px`1)^2);
      then
A51:  (px`2)^2-1=0 or (px`2)^2+(px`1)^2=0 by XCMPLX_1:6;
      now
        per cases by A49,A51,COMPLEX1:1,SQUARE_1:41;
        case
          px`2=1;
          hence -1=px`2 & -1<=px`1 & px`1<=1 or px`2=1 & -1<=px`1 & px`1<=1 or
-1=px`1 & -1<=px`2 & px`2<=1 or 1=px`1 & -1<=px`2 & px`2<=1 by A43,A41,A40,A46,
XREAL_1:64;
        end;
        case
          px`2=-1;
          hence -1=px`2 & -1<=px`1 & px`1<=1 or px`2=1 & -1<=px`1 & px`1<=1 or
-1=px`1 & -1<=px`2 & px`2<=1 or 1=px`1 & -1<=px`2 & px`2<=1 by A43,A40,A46,
XREAL_1:64;
        end;
      end;
      then
A52:  dom Sq_Circ=the carrier of TOP-REAL 2 & px in Kb by A1,FUNCT_2:def 1;
      px`1<=px`2 & -px`2<=px`1 or px`1>=px`2 & px`1<=-px`2 by A43,A41,A40,A46,
XREAL_1:64;
      then
A53:  Sq_Circ.px=|[px`1/sqrt(1+(px`1/px`2)^2),px`2/sqrt(1+(px`1/px`2 )^2
      )]| by A49,Th4,JGRAPH_2:3;
      px`2/sqrt(1+(px`1/px`2)^2)=q`2 by A43,A40,A44,XCMPLX_1:89;
      hence ex x being set st x in dom Sq_Circ & x in Kb & y=Sq_Circ.x by A18
,A53,A45,A52,EUCLID:53;
    end;
  end;
  hence thesis by FUNCT_1:def 6;
end;
