reserve p,p1,p2,p3,q,q1,q2 for Point of TOP-REAL 2,
  i for Nat,
  lambda for Real;

theorem Th23:
  for a,b,r be Real, Cb being Subset of TOP-REAL 2 st r>0 &
  Cb={p where p is Point of TOP-REAL 2: |.(p- |[a,b]|).|=r}
  holds Cb is being_simple_closed_curve
proof
  let a,b,r be Real, Cb be Subset of TOP-REAL 2;
  assume that
A1: r>0 and
A2: Cb={p where p is Point of TOP-REAL 2: |.(p- |[a,b]|).|=r};
A3: (|[r,0]|)`1=r by EUCLID:52;
A4: (|[r,0]|)`2=0 by EUCLID:52;
  |.(|[r+a,b]| - |[a,b]|).|=|.(|[r+a,0+b]| - |[a,b]|).|
    .=|.(|[r,0]|+|[a,b]|- |[a,b]|).| by EUCLID:56
    .= |.(|[r,0]|+(|[a,b]|- |[a,b]|)).| by RLVECT_1:def 3
    .=|.|[r,0]|+(0.TOP-REAL 2).| by RLVECT_1:5
    .=|.|[r,0]|.| by RLVECT_1:4
    .=sqrt(r^2+0^2) by A3,A4,JGRAPH_3:1
    .=r by A1,SQUARE_1:22;
  then |[r+a,b]| in Cb by A2;
  then reconsider Cbb=Cb as non empty Subset of TOP-REAL 2;
  set v= |[1,0]|;
A5: v`1=1 by EUCLID:52;
  v`2=0 by EUCLID:52;
  then |.v.|=sqrt(1^2+0^2) by A5,JGRAPH_3:1
    .=1;
  then
A6: |[1,0]| in {q: |.q.|=1};
  defpred P[Point of TOP-REAL 2] means |.$1.|=1;
  {q where q is Element of TOP-REAL 2:P[q]}
  is Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
  then reconsider Kb= {q: |.q.|=1} as non empty Subset of TOP-REAL 2 by A6;
A7: the carrier of (TOP-REAL 2)|Kb=Kb by PRE_TOPC:8;
  set SC= AffineMap(r,a,r,b);
A8: SC is one-to-one by A1,JGRAPH_2:44;
A9: dom SC = the carrier of TOP-REAL 2 by FUNCT_2:def 1;
A10: dom (SC|Kb)=(dom SC)/\ Kb by RELAT_1:61
    .=the carrier of ((TOP-REAL 2)|Kb) by A7,A9,XBOOLE_1:28;
A11: rng (SC|Kb) c= (SC|Kb).:(the carrier of ((TOP-REAL 2)|Kb))
  proof
    let u be object;
    assume u in rng (SC|Kb);
    then ex z being object st ( z in dom ((SC|Kb)))&( u=(SC|Kb).z) by
FUNCT_1:def 3;
    hence thesis by A10,FUNCT_1:def 6;
  end;
  (SC|Kb).: (the carrier of ((TOP-REAL 2)|Kb)) = SC.:Kb by A7,RELAT_1:129
    .= Cb by A1,A2,Th20
    .=the carrier of (TOP-REAL 2)|Cbb by PRE_TOPC:8;
  then reconsider f0=SC|Kb
  as Function of (TOP-REAL 2)|Kb, (TOP-REAL 2)|Cbb by A10,A11,FUNCT_2:2;
  rng (SC|Kb) c= the carrier of (TOP-REAL 2);
  then reconsider f00=f0 as Function
  of (TOP-REAL 2)|Kb,TOP-REAL 2 by A10,FUNCT_2:2;
A12: rng f0 = (SC|Kb).: (the carrier of ((TOP-REAL 2)|Kb)) by RELSET_1:22
    .= SC.:Kb by A7,RELAT_1:129
    .= Cb by A1,A2,Th20;
A13: f0 is one-to-one by A8,FUNCT_1:52;
  Kb is compact by Th22,JGRAPH_3:26;
  then ex f1 being Function of (TOP-REAL 2)|Kb,(TOP-REAL 2)|Cbb st
  f00=f1 & f1 is being_homeomorphism by A12,A13,JGRAPH_1:46,TOPMETR:7;
  hence thesis by Th21,JGRAPH_3:26;
end;
