reserve a, b, c, d, r, s for Real,
  n for Element of NAT,
  p, p1, p2 for Point of TOP-REAL 2,
  x, y for Point of TOP-REAL n,
  C for Simple_closed_curve,
  A, B, P for Subset of TOP-REAL 2,
  U, V for Subset of (TOP-REAL 2)|C`,
  D for compact with_the_max_arc Subset of TOP-REAL 2;

theorem Th23:
  for r being non zero Real holds Cl Ball(x,r) = cl_Ball(x,r)
proof
  let r be non zero Real;
  thus Cl Ball(x,r) c= cl_Ball(x,r) by TOPREAL9:16,TOPS_1:5;
  per cases;
  suppose
    Ball(x,r) is empty;
    then r < 0;
    hence thesis;
  end;
  suppose
A1: Ball(x,r) is non empty;
    let a be object;
    assume
A2: a in cl_Ball(x,r);
    then reconsider a as Point of TOP-REAL n;
    reconsider ae = a as Point of Euclid n by TOPREAL3:8;
A3: 0 < r by A1;
    for s being Real st 0 < s & s < r holds Ball(ae,s) meets Ball(x,r)
    proof
      let s be Real such that
A4:   0 < s and
A5:   s < r;
      now
A6:     Ball(x,r) \/ Sphere(x,r) = cl_Ball(x,r) by TOPREAL9:18;
        per cases by A2,A6,XBOOLE_0:def 3;
        suppose
A7:       a in Ball(x,r);
          |.a-a.| = 0 by TOPRNS_1:28;
          then a in Ball(a,s) by A4,TOPREAL9:7;
          hence Ball(a,s) meets Ball(x,r) by A7,XBOOLE_0:3;
        end;
        suppose
A8:       a in Sphere(x,r);
          then
A9:       |. a-x .| = r by TOPREAL9:9;
          |. x-x .| = 0 by TOPRNS_1:28;
          then
A10:      x in Ball(x,r) by A3,TOPREAL9:7;
          set z = s/(2*r);
          set q = (1-z)*a+z*x;
          1 * r < 2*r by A3,XREAL_1:68;
          then s < 2*r by A5,XXREAL_0:2;
          then
A11:      z < 1 by A4,XREAL_1:189;
          0 < 2*r by A3,XREAL_1:129;
          then
A12:      0 < z by A4,XREAL_1:139;
A13:      q in LSeg(a,x) by A3,A4,A11;
          Ball(x,r) misses Sphere(x,r) by TOPREAL9:19;
          then
A14:      a <> x by A8,A10,XBOOLE_0:3;
          then
A15:      q <> a by A12,TOPREAL9:4;
          q <> x by A11,A14,TOPREAL9:4;
          then not q in {a,x} by A15,TARSKI:def 2;
          then
A16:      q in LSeg(a,x) \ {a,x} by A13,XBOOLE_0:def 5;
A17:      LSeg(a,x) \ {a,x} c= Ball(x,r) by A8,Th20;
          q-a = (1-z)*a - a + z*x by RLVECT_1:def 3
            .= 1 * a - z*a - a + z*x by RLVECT_1:35
            .= a - z*a - a + z*x by RLVECT_1:def 8
            .= a +- z*a +- a + z*x
            .= a +- a +- z*a + z*x by RLVECT_1:def 3
            .= a - a - z*a + z*x
            .= 0.TOP-REAL n - z*a + z*x by RLVECT_1:5
            .= z*x - z*a by RLVECT_1:4
            .= z*(x-a) by RLVECT_1:34;
          then |.q-a.| = |.z.| * |.x-a.| by TOPRNS_1:7
            .= z*|.x-a.| by A3,A4,ABSVALUE:def 1
            .= z*|. a-x .| by TOPRNS_1:27
            .= s/2 by A9,XCMPLX_1:92;
          then
A18:      q in Sphere(a,s/2) by TOPREAL9:9;
          s/2 < s/1 by A4,XREAL_1:76;
          then Sphere(a,s/2) c= Ball(a,s) by Th22;
          hence Ball(a,s) meets Ball(x,r) by A16,A17,A18,XBOOLE_0:3;
        end;
      end;
      hence thesis by TOPREAL9:13;
    end;
    hence thesis by A3,GOBOARD6:93;
  end;
end;
