reserve x for set,
  K for Ring,
  r for Scalar of K,
  V for LeftMod of K,
  a,b,a1,a2 for Vector of V,
  A,A1,A2 for Subset of V,
  l for Linear_Combination of A,
  W for Subspace of V,
  Li for FinSequence of Submodules(V);
reserve S1,S2 for Element of V..W;
reserve S for Element of V.W;

theorem Th23:
  V/W is strict LeftMod of K
proof
  now
    let x,y be Scalar of K, v,w be Vector of V/W;
    consider a such that
A1: v = a/W by Th20;
    consider b such that
A2: w = b/W by Th20;
A3: (x*a)/W = x*v by A1,Th22;
A4: (x*b)/W = x*w by A2,Th22;
A5: (y*a)/W = y*v by A1,Th22;
    thus x*(v+w) = x*((a+b)/W) by A1,A2,Th22
      .= (x*(a+b))/W by Th22
      .= (x*a+x*b)/W by VECTSP_1:def 14
      .= x*v+x*w by A3,A4,Th22;
    thus (x+y)*v = ((x+y)*a)/W by A1,Th22
      .= (x*a+y*a)/W by VECTSP_1:def 15
      .= x*v+y*v by A3,A5,Th22;
    thus (x*y)*v = ((x*y)*a)/W by A1,Th22
      .= (x*(y*a))/W by VECTSP_1:def 16
      .= x*((y*a)/W) by Th22
      .= x*(y*v) by A1,Th22;
    thus 1_K*v = (1_K*a)/W by A1,Th22
      .= v by A1;
  end;
  hence thesis by Lm2,VECTSP_1:def 14,def 15,def 16,def 17;
end;
