reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;

theorem Th23:
  for h1,h2 be PartFunc of CNS1,CNS2, seq be sequence of CNS1 st
rng seq c= dom h1 /\ dom h2 holds (h1+h2)/*seq=h1/*seq+h2/*seq & (h1-h2)/*seq=
  h1/*seq-h2/*seq
proof
  let h1,h2 be PartFunc of CNS1,CNS2;
  let seq be sequence of CNS1;
A1: dom h1 /\ dom h2 c= dom h1 by XBOOLE_1:17;
A2: dom h1 /\ dom h2 c= dom h2 by XBOOLE_1:17;
  assume
A3: rng seq c= dom h1 /\ dom h2;
  then
A4: rng seq c= dom (h1 + h2) by VFUNCT_1:def 1;
  now
    let n be Nat;
A5:  n in NAT by ORDINAL1:def 12;
A6: seq.n in dom (h1 + h2) by A4,Th4;
    thus ((h1+h2)/*seq).n = (h1+h2)/.(seq.n) by A4,FUNCT_2:109,A5
      .= h1/.(seq.n) + h2/.(seq.n) by A6,VFUNCT_1:def 1
      .= (h1/*seq).n + h2/.(seq.n) by A3,A1,FUNCT_2:109,XBOOLE_1:1,A5
      .= (h1/*seq).n + (h2/*seq).n by A3,A2,FUNCT_2:109,XBOOLE_1:1,A5;
  end;
  hence (h1+h2)/*seq=h1/*seq+h2/*seq by NORMSP_1:def 2;
A7: rng seq c= dom (h1 - h2) by A3,VFUNCT_1:def 2;
  now
    let n be Nat;
A8:   n in NAT by ORDINAL1:def 12;
A9: seq.n in dom (h1 - h2) by A7,Th4;
    thus ((h1-h2)/*seq).n = (h1-h2)/.(seq.n) by A7,FUNCT_2:109,A8
      .= h1/.(seq.n) - h2/.(seq.n) by A9,VFUNCT_1:def 2
      .= (h1/*seq).n - h2/.(seq.n) by A3,A1,FUNCT_2:109,XBOOLE_1:1,A8
      .= (h1/*seq).n - (h2/*seq).n by A3,A2,FUNCT_2:109,XBOOLE_1:1,A8;
  end;
  hence thesis by NORMSP_1:def 3;
end;
