 reserve RNS1,RNS2 for RealLinearSpace;

theorem Th23:
for RNS be RealNormSpace
  holds ex T be NormedLinearTopSpace
     st the NORMSTR of RNS = the NORMSTR of T
proof
let RNS0 be RealNormSpace;
reconsider RNS = the NORMSTR of RNS0 as strict RealNormSpace by Th22;
set LRNS = LinearTopSpaceNorm RNS;
A1: the carrier of LRNS = the carrier of RNS
  & 0. LRNS = 0. RNS
  & the addF of LRNS = the addF of RNS
  & the Mult of LRNS = the Mult of RNS
  & the topology of LRNS = the topology of TopSpaceNorm RNS
      by NORMSP_2:def 4;
reconsider N = the normF of RNS as Function of the carrier of LRNS, REAL by A1;
set W = RLNormTopStruct
     (# the carrier of LRNS,
        the ZeroF of LRNS,
        the addF of LRNS,
        the Mult of LRNS,
        the topology of LRNS,
    N #);
now
  let x, y be Point of W;
  let a be Real;
  reconsider u = x, w = y as VECTOR of RNS by NORMSP_2:def 4;
  ||.u.|| = 0 iff u =0.RNS by NORMSP_0:def 5,def 6;
  hence ||.x.|| = 0 iff x = 0.W by A1;
  thus ||.(a*x).|| = ||.(a*u).|| by NORMSP_2:def 4
                  .= |.a.| * ||.u.|| by NORMSP_1:def 1
                  .= |.a.| * ||.x.||;
   ||.(u+w).|| <= ||.u.|| + ||.w.|| by NORMSP_1:def 1;
  hence ||.(x + y).|| <= ||.x.|| + ||.y.|| by NORMSP_2:def 4;
end; then
A2: W is discerning reflexive RealNormSpace-like;
A3: W is TopSpace-like right_complementable
         Abelian add-associative right_zeroed
         vector-distributive scalar-distributive
         scalar-associative scalar-unital
         add-continuous Mult-continuous
  proof
  A4: for x1, x2 being Point of W
      for V being Subset of W st V is open & x1+x2 in V holds
        ex V1, V2 being Subset of W st
        V1 is open & V2 is open & x1 in V1 & x2 in V2 & V1+V2 c= V
    proof
    let x1, x2 be Point of W;
    let V be Subset of W;
    assume A5: V is open & x1+x2 in V;
    reconsider V0 = V as Subset of LRNS;
    reconsider xx1=x1, xx2=x2 as Point of LRNS;
    V0 is open & xx1+xx2 in V0 by A5; then
    consider V10, V20 being Subset of LRNS such that
    A6: V10 is open & V20 is open & xx1 in V10 & xx2 in V20 & V10+V20 c= V0
        by RLTOPSP1:def 8;
    reconsider V1=V10, V2=V20 as Subset of W;
    A7: for z be object holds z in V10+V20 iff z in V1+V2
      proof
        let z be object;
        hereby assume z in V10 + V20; then
          consider u0, v0 be Element of LRNS such that
          A8: z=u0+v0 & u0 in V10 & v0 in V20;
          reconsider u=u0, v=v0 as Element of W;
          u+v = u0+v0;
          hence z in V1+V2 by A8;
        end;
        assume z in V1 + V2; then
        consider u0, v0 be Element of W such that
        A9: z = u0+v0 & u0 in V10 & v0 in V20;
        reconsider u=u0, v=v0 as Element of LRNS;
        u+v = u0+v0;
        hence z in V10+V20 by A9;
      end;
    take V1,V2;
    thus thesis by A6,A7;
  end;
  A10: now
    let a, b be Real;
    let v be VECTOR of W;
    reconsider v1 = v as VECTOR of LRNS;
    A11: (a*v1) + (b*v1) = (a*v) + (b*v);
    (a+b) * v = (a+b) * v1;
    hence (a+b) * v = (a*v) + (b*v) by A11, RLVECT_1:def 6;
  end;
  A12: for a being Real
       for x being Point of W
       for V being Subset of W st V is open & a * x in V holds
         ex r being positive Real,
            Z being Subset of W st Z is open & x in Z &
         for s being Real st |.(s - a).| < r holds s * Z c= V
  proof
    let a be Real;
    let x be Point of W,
        V be Subset of W;
    assume A13: V is open & a * x in V;
    reconsider V0 = V as Subset of LRNS;
    reconsider xx=x as Point of LRNS;
    V0 is open & a*xx in V0 by A13; then
    consider r being positive Real,
            Z0 being Subset of LRNS such that
    A14: Z0 is open & xx in Z0 &
         for s being Real st |.(s - a).| < r holds
             s * Z0 c= V0 by RLTOPSP1:def 9;
    reconsider Z= Z0 as Subset of W;
    take r,Z;
    for s being Real st |.(s - a).| < r holds s * Z c= V
    proof
      let s be Real;
      assume |.(s - a).| < r; then
      A15: s * Z0 c= V0 by A14;
      for z be object holds z in s * Z0 iff z in s * Z
      proof
        let z be object;
        hereby assume z in s * Z0; then
          consider u0 be Element of LRNS such that
          A16: z=s*u0 & u0 in Z0;
          reconsider u =u0 as Element of W;
          s*u = s*u0;
          hence z in s * Z by A16;
        end;
        assume z in s * Z; then
        consider u0 be Element of W such that
        A17: z=s*u0 & u0 in Z0;
        reconsider u = u0 as Element of LRNS;
        s*u = s*u0;
        hence z in s * Z0 by A17;
      end;
      hence thesis by A15;
    end;
    hence thesis by A14;
  end;
  A18: W is Abelian
  proof
    let v, w be VECTOR of W;
    reconsider v1 = v, w1 = w as VECTOR of LRNS;
    thus v+w = v1+w1
            .= w1+v1
            .= w+v;
  end;
  A19: W is add-associative
  proof
    let v, w, x be VECTOR of W;
    reconsider v1 = v, w1 = w, x1 = x as VECTOR of LRNS;
    thus (v+w)+x = (v1+w1)+x1
                .= v1+(w1+x1) by RLVECT_1:def 3
                .= v+(w+x);
  end;
  A20: W is right_zeroed
  proof
    let v be VECTOR of W;
    reconsider v1 = v as VECTOR of LRNS;
    thus v+(0.W) = v1+(0.LRNS)
                .= v;
  end;
  A21: W is right_complementable
  proof
    let v be VECTOR of W;
    reconsider v1 = v as VECTOR of LRNS;
    reconsider w = -v1 as VECTOR of W;
    take w;
    thus v+w = v1-v1
            .= 0.LRNS by RLVECT_1:15
            .= 0.W;
  end;
  A22: now
    let a, b be Real;
    let v be VECTOR of W;
    reconsider v1 = v as VECTOR of LRNS;
    a*(b*v1) = a*(b*v); then
    (a*b)*v1 = a*(b*v) by RLVECT_1:def 7;
    hence (a*b)*v = a*(b*v);
  end;
  A23: now
    let a be Real;
    let v, w be VECTOR of W;
    reconsider v1 = v, w1 = w as VECTOR of LRNS;
    A24: (a*v1)+(a*w1) = (a*v)+(a*w);
    a*(v+w) = a*(v1+w1);
    hence a*(v+w) = (a*v)+(a*w) by A24, RLVECT_1:def 5;
  end;
  now
    let v be VECTOR of W;
    reconsider v1 = v as VECTOR of LRNS;
    thus 1*v = 1*v1
            .= v by RLVECT_1:def 8;
  end;
  hence thesis by A4, A10, A12, A18, A19, A20, A21, A22, A23, PRE_TOPC:def 1;
end;
now
  let p, q be Point of W;
  reconsider p1 = p, q1 = q as Point of LRNS;
  assume p <> q; then
  consider W1, V1 being Subset of LRNS such that
  A25: W1 is open and
  A26: V1 is open and
  A27: p1 in W1 & q1 in V1 & W1 misses V1 by PRE_TOPC:def 10;
  reconsider WW = W1, V = V1 as Subset of W;
  A28: V is open by A26;
  WW is open by A25;
  hence ex b1, b2 being Element of bool the carrier of W st
  b1 is open & b2 is open & p in b1 & q in b2 & b1 misses b2 by A27, A28;
end; then
W is T_2; then
reconsider W as NormedLinearTopSpace by A1, A2, A3, C0SP3:def 6;
take W;
thus the NORMSTR of RNS0 = the NORMSTR of W by A1;
end;
