reserve D for set;
reserve x,x0,x1,x2,y,y0,y1,y2,z,z0,z1,z2,r,s,t for Real;
reserve p,a,u,u0 for Element of REAL 3;
reserve n,m,k for Element of NAT;
reserve f,f1,f2,f3,g for PartFunc of REAL 3,REAL;
reserve R,R1,R2 for RestFunc;
reserve L,L1,L2 for LinearFunc;

theorem
  f is_partial_differentiable`2_on D implies
  D c= dom f & for u st u in D holds f is_partial_differentiable_in u,2
proof
    assume
A1: f is_partial_differentiable`2_on D;
    hence D c= dom f;
    set g = f|D;
    let u0 be Element of REAL 3;
    assume u0 in D;then
 g is_partial_differentiable_in u0,2 by A1;
    then consider x0,y0,z0 being Real such that
A2: u0 = <*x0,y0,z0*> & ex N being Neighbourhood of y0
    st N c= dom SVF1(2,g,u0) & ex L,R st for y st y in N holds
    SVF1(2,g,u0).y - SVF1(2,g,u0).y0 = L.(y-y0) + R.(y-y0) by Th14;
    consider N being Neighbourhood of y0 such that
A3: N c= dom SVF1(2,g,u0) & ex L,R st for y st y in N holds
    SVF1(2,g,u0).y - SVF1(2,g,u0).y0 = L.(y-y0) + R.(y-y0) by A2;
    for y st y in dom (SVF1(2,g,u0)) holds y in dom (SVF1(2,f,u0))
    proof
      let y;
      assume y in dom (SVF1(2,g,u0));
  then
A4: y in dom reproj(2,u0) & reproj(2,u0).y in dom (f|D) by FUNCT_1:11;
      dom (f|D) = dom f /\ D by RELAT_1:61;then
      dom (f|D) c= dom f by XBOOLE_1:17;
      hence thesis by A4,FUNCT_1:11;
    end;
    then for y be object st y in dom (SVF1(2,g,u0))
         holds y in dom (SVF1(2,f,u0));
    then dom (SVF1(2,g,u0)) c= dom (SVF1(2,f,u0));then
A5: N c= dom (SVF1(2,f,u0)) by A3;
    consider L,R such that
A6: for y st y in N holds SVF1(2,g,u0).y - SVF1(2,g,u0).y0 =
      L.(y-y0) + R.(y-y0) by A3;
    for y st y in N holds SVF1(2,f,u0).y - SVF1(2,f,u0).y0 =
      L.(y-y0) + R.(y-y0)
    proof
      let y;
      assume
 A7: y in N;
 A8: for y st y in dom SVF1(2,g,u0) holds SVF1(2,g,u0).y = SVF1(2,f,u0).y
      proof
        let y;
        assume
   A9: y in dom (SVF1(2,g,u0));
   then
A10: y in dom reproj(2,u0) & reproj(2,u0).y in dom (f|D) by FUNCT_1:11;
        SVF1(2,g,u0).y = (f|D).(reproj(2,u0).y) by A9,FUNCT_1:12
        .= f.(reproj(2,u0).y) by A10,FUNCT_1:47
        .= SVF1(2,f,u0).y by A10,FUNCT_1:13;
        hence thesis;
      end;
 A11: y0 in N by RCOMP_1:16;
      L.(y-y0) + R.(y-y0) = SVF1(2,g,u0).y - SVF1(2,g,u0).y0 by A6,A7
      .= SVF1(2,f,u0).y - SVF1(2,g,u0).y0 by A3,A7,A8
      .= SVF1(2,f,u0).y - SVF1(2,f,u0).y0 by A3,A8,A11;
      hence thesis;
    end;
    hence thesis by A2,A5,Th14;
end;
