reserve z1,z2,z3,z4,z for Quaternion;

theorem
  <k>*z1+z1*<k> = [*-2*Im3 z1,0,0,2*Rea z1*]
proof
  set z = <k>;
A1: z*z1 =
  (Rea z * Rea z1 - Im1 z * Im1 z1 - Im2 z * Im2 z1 - Im3 z * Im3 z1) +
  (Rea z * Im1 z1 + Im1 z * Rea z1 + Im2 z * Im3 z1 - Im3 z * Im2 z1)*<i> +
  (Rea z * Im2 z1 + Im2 z * Rea z1 + Im3 z * Im1 z1 - Im1 z * Im3 z1)*<j> +
  (Rea z * Im3 z1 + Im3 z * Rea z1 + Im1 z * Im2 z1 - Im2 z * Im1 z1)*<k>
    by QUATERNI:93
   .= [*-Im3 z1,-Im2 z1,Im1 z1,Rea z1 *] by QUATERN2:1,QUATERNI:31; then
A2: Im2(z*z1)=Im1 z1 & Im3(z*z1) =Rea z1 by QUATERNI:23;
A3: z1*z =
  (Rea z1 * Rea z - Im1 z1 * Im1 z - Im2 z1 * Im2 z - Im3 z1 * Im3 z) +
  (Rea z1 * Im1 z + Im1 z1 * Rea z + Im2 z1 * Im3 z - Im3 z1 * Im2 z)*<i> +
  (Rea z1 * Im2 z + Im2 z1 * Rea z + Im3 z1 * Im1 z - Im1 z1 * Im3 z)*<j> +
  (Rea z1 * Im3 z + Im3 z1 * Rea z + Im1 z1 * Im2 z - Im2 z1 * Im1 z)*<k>
    by QUATERNI:93
  .= [*-Im3 z1,Im2 z1,-Im1 z1,Rea z1*] by QUATERN2:1,QUATERNI:31; then
A4: Rea(z1*z)= -Im3 z1 & Im1 (z1*z)=Im2 z1 by QUATERNI:23;
A5: Im2(z1*z)=-Im1 z1 & Im3(z1*z) = Rea z1 by A3,QUATERNI:23;
  Rea(z*z1)= -Im3 z1 & Im1 (z*z1)=-Im2 z1 by A1,QUATERNI:23; then
  z1*z+z*z1 = (-Im3 z1+(-Im3 z1)) + (-Im2 z1+Im2 z1)*<i> + (Im1 z1 -Im1 z1
  )*<j> +(Rea z1 +Rea z1)*<k> by A2,A4,A5,QUATERNI:92;
  hence thesis by QUATERN2:1;
end;
