reserve x,y for set,
        r,s for Real,
        S for non empty addLoopStr,
        LS,LS1,LS2 for Linear_Combination of S,
        G for Abelian add-associative right_zeroed right_complementable
          non empty addLoopStr,
        LG,LG1,LG2 for Linear_Combination of G,
        g,h for Element of G,
        RLS for non empty RLSStruct,
        R for vector-distributive scalar-distributive scalar-associative
        scalar-unitalnon empty RLSStruct,
        AR for Subset of R,
        LR,LR1,LR2 for Linear_Combination of R,
        V for RealLinearSpace,
        v,v1,v2,w,p for VECTOR of V,
        A,B for Subset of V,
        F1,F2 for Subset-Family of V,
        L,L1,L2 for Linear_Combination of V;

theorem Th23:
  r <> 0 implies Carrier (r(*)LR) = r * Carrier LR
  proof
    assume A1: r<>0;
    thus Carrier(r(*)LR)c=r*Carrier LR by Th22;
    let x be object;
    assume x in r*Carrier LR;
    then consider v be Element of R such that
    A2: x=r*v and
    A3: v in Carrier LR;
    r"*(r*v) = (r"*r)*v by RLVECT_1:def 7
            .= 1*v by A1,XCMPLX_0:def 7
            .= v by RLVECT_1:def 8;
    then A4: LR.v=(r(*)LR).x by A1,A2,Def2;
    LR.v<>0 by A3,RLVECT_2:19;
    hence thesis by A2,A4;
  end;
