reserve m,n for Nat,
  I for Program of SCM+FSA,
  s,s1,s2 for State of SCM+FSA,
  a for Int-Location,
  f for FinSeq-Location,
  p,p1,p2 for Instruction-Sequence of SCM+FSA;

theorem Th21:
  for I being keepInt0_1 InitHalting really-closed Program of SCM+FSA,
      j being sequential Instruction of SCM+FSA
  holds IExec(I ";" j,p,s).a = Exec(j,IExec(I,p,s)).a
proof
  let I be keepInt0_1 InitHalting really-closed Program of SCM+FSA,
      j be sequential Instruction of SCM+FSA;
  set Mj = Macro j;
  set SA = Start-At (IC IExec(Mj,p,IExec(I,p,s)) + card I, SCM+FSA);
A1: not a in dom SA by SCMFSA_2:102;
A2: DataPart Initialized IExec(I,p,s) = DataPart IExec(I,p,s) by Th20;
  a in Int-Locations by AMI_2:def 16;
  then
A3: a in Data-Locations SCM+FSA by SCMFSA_2:100,XBOOLE_0:def 3;
  thus IExec(I ";" j,p,s).a = IncIC(IExec(Mj,p,IExec(I,p,s)),card I).a by Th17
    .= IExec(Mj,p,IExec(I,p,s)).a by A1,FUNCT_4:11
    .= ( Exec(j, Initialized IExec(I,p,s))).a by SCMFSA6C:5
    .= (DataPart Exec(j, Initialized IExec(I,p,s))).a by A3,FUNCT_1:49
    .= (DataPart Exec(j, IExec(I,p,s))).a by A2,SCMFSA6C:4
    .= Exec(j, IExec(I,p,s)).a by A3,FUNCT_1:49;
end;
