reserve X,Y,Z,Z1,Z2,D for set,x,y for object;
reserve SFX,SFY,SFZ for set;

theorem
  SFX meets SFY implies meet SFX /\ meet SFY = meet INTERSECTION(SFX,SFY )
proof
  set y = the Element of SFX /\ SFY;
  assume
A1: SFX /\ SFY <> {};
  then
A2: SFY <> {};
A3: y in SFX by A1,XBOOLE_0:def 4;
A4: y in SFY by A1,XBOOLE_0:def 4;
A5: SFX <> {} by A1;
A6: meet INTERSECTION(SFX,SFY) c= meet SFX /\ meet SFY
  proof
    let x be object such that
A7: x in meet INTERSECTION(SFX,SFY);
    for Z st Z in SFY holds x in Z
    proof
      let Z;
      assume Z in SFY;
      then y /\ Z in INTERSECTION(SFX,SFY) by A3,Def5;
      then x in y /\ Z by A7,Def1;
      hence thesis by XBOOLE_0:def 4;
    end;
    then
A8: x in meet SFY by A2,Def1;
    for Z st Z in SFX holds x in Z
    proof
      let Z;
      assume Z in SFX;
      then Z /\ y in INTERSECTION(SFX,SFY) by A4,Def5;
      then x in Z /\ y by A7,Def1;
      hence thesis by XBOOLE_0:def 4;
    end;
    then x in meet SFX by A5,Def1;
    hence thesis by A8,XBOOLE_0:def 4;
  end;
A9: y /\ y in INTERSECTION(SFX,SFY) by A3,A4,Def5;
  meet SFX /\ meet SFY c= meet INTERSECTION(SFX,SFY)
  proof
    let x be object;
    assume x in meet SFX /\ meet SFY;
    then
A10: x in meet SFX & x in meet SFY by XBOOLE_0:def 4;
    for Z st Z in INTERSECTION(SFX,SFY) holds x in Z
    proof
      let Z;
      assume Z in INTERSECTION(SFX,SFY);
      then consider Z1,Z2 such that
A11:  Z1 in SFX & Z2 in SFY and
A12:  Z = Z1 /\ Z2 by Def5;
      x in Z1 & x in Z2 by A10,A11,Def1;
      hence thesis by A12,XBOOLE_0:def 4;
    end;
    hence thesis by A9,Def1;
  end;
  hence thesis by A6;
end;
