reserve A, B for non empty set,
  A1, A2, A3 for non empty Subset of A;
reserve X for TopSpace;
reserve X for non empty TopSpace;
reserve X1, X2 for non empty SubSpace of X;
reserve X0, X1, X2, Y1, Y2 for non empty SubSpace of X;

theorem
  Y1 meets Y2 & Y1 is SubSpace of X1 & Y2 is SubSpace of X2 implies Y1
  meet Y2 is SubSpace of X1 meet X2
proof
  assume
A1: Y1 meets Y2;
  assume Y1 is SubSpace of X1 & Y2 is SubSpace of X2;
  then
A2: the carrier of Y1 c= the carrier of X1 & the carrier of Y2 c= the
  carrier of X2 by TSEP_1:4;
  (the carrier of Y1) meets (the carrier of Y2) by A1,TSEP_1:def 3;
  then (the carrier of X1) /\ (the carrier of X2) <> {} by A2,XBOOLE_1:3,27;
  then (the carrier of X1) meets (the carrier of X2);
  then
A3: X1 meets X2 by TSEP_1:def 3;
  (the carrier of Y1) /\ (the carrier of Y2) c= (the carrier of X1) /\ (
  the carrier of X2) by A2,XBOOLE_1:27;
  then (the carrier of Y1) /\ (the carrier of Y2) c= the carrier of (X1 meet
  X2) by A3,TSEP_1:def 4;
  then the carrier of (Y1 meet Y2) c= the carrier of (X1 meet X2) by A1,
TSEP_1:def 4;
  hence thesis by TSEP_1:4;
end;
