reserve R for non empty RelStr,
  N for net of R,
  i for Element of N;

theorem Th23:
  for R being complete LATTICE, N being constant net of R
  holds the_value_of N = lim_inf N
proof
  let R be complete LATTICE, N be constant net of R;
  set X = the set of all "/\"({N.i where i is Element of N:
  i >= j},R) where j is Element of N;
  set j = the Element of N;
A1: N.j is_>=_than X
  proof
    let b be Element of R;
    assume b in X;
    then consider j0 being Element of N such that
A2: b = "/\"({N.i where i is Element of N: i >= j0},R);
    reconsider j0 as Element of N;
    consider i0 being Element of N such that
A3: i0 >= j0 and i0 >= j0 by YELLOW_6:def 3;
A4: N.i0 in {N.i where i is Element of N: i >= j0} by A3;
    N.i0 = the_value_of N by YELLOW_6:16
      .= N.j by YELLOW_6:16;
    hence thesis by A2,A4,YELLOW_2:22;
  end;
A5: for b being Element of R st b is_>=_than X holds N.j <= b
  proof
    let b be Element of R;
    set Y = {N.i where i is Element of N: i >= j};
A6: "/\"(Y,R) in X;
    assume b is_>=_than X;
    then
A7: b >= "/\"(Y,R) by A6;
A8: N.j is_<=_than Y
    proof
      let c be Element of R;
      assume c in Y;
      then consider i0 being Element of N such that
A9:   c = N.i0 and i0 >= j;
      N.j = the_value_of N by YELLOW_6:16
        .= N.i0 by YELLOW_6:16;
      hence N.j <= c by A9;
    end;
    for b being Element of R st b is_<=_than Y holds N.j >= b
    proof
      let c be Element of R;
      consider i0 being Element of N such that
A10:  i0 >= j and i0 >= j by YELLOW_6:def 3;
A11:  N.i0 in Y by A10;
      assume
A12:  c is_<=_than Y;
      N.j = the_value_of N by YELLOW_6:16
        .= N.i0 by YELLOW_6:16;
      hence thesis by A11,A12;
    end;
    hence thesis by A7,A8,YELLOW_0:33;
  end;
  thus the_value_of N = N.j by YELLOW_6:16
    .= lim_inf N by A1,A5,YELLOW_0:32;
end;
