reserve X1, X2, Y for non empty RelStr,
  f for Function of [:X1, X2:], Y,
  x for Element of X1,
  y for Element of X2;

theorem Th23:
  for I being non empty set for J being RelStr-yielding non-Empty
reflexive-yielding ManySortedSet of I st for i being Element of I holds J.i is
complete LATTICE for X being Subset of product J, i being Element of I holds (
  inf X).i = inf pi(X,i)
proof
  let I be non empty set;
  let J be RelStr-yielding non-Empty reflexive-yielding ManySortedSet of I;
  assume
A1: for i being Element of I holds J.i is complete LATTICE;
  then reconsider L = product J as complete LATTICE by WAYBEL_3:31;
  let X be Subset of product J, i be Element of I;
A2: L is complete;
  then
A3: inf X is_<=_than X by YELLOW_0:33;
A4: (inf X).i is_<=_than pi(X,i)
  proof
    let a be Element of J.i;
    assume a in pi(X,i);
    then consider f being Function such that
A5: f in X and
A6: a = f.i by CARD_3:def 6;
    reconsider f as Element of product J by A5;
    inf X <= f by A3,A5;
    hence thesis by A6,WAYBEL_3:28;
  end;
A7: now
    let a be Element of J.i;
    set f = (inf X)+*(i,a);
A8: dom f = dom inf X by FUNCT_7:30;
A9: dom inf X = I by WAYBEL_3:27;
    now
      let j be Element of I;
      j = i or j <> i;
      then f.j = (inf X).j or f.j = a & j = i by A9,FUNCT_7:31,32;
      hence f.j is Element of J.j;
    end;
    then reconsider f as Element of product J by A8,WAYBEL_3:27;
    assume
A10: a is_<=_than pi(X,i);
    f is_<=_than X
    proof
      let g be Element of product J;
      assume g in X;
      then
A11:  g >= inf X & g.i in pi(X,i) by A2,CARD_3:def 6,YELLOW_2:22;
      now
        let j be Element of I;
        j = i or j <> i;
        then f.j = (inf X).j or f.j = a & j = i by A9,FUNCT_7:31,32;
        hence f.j <= g.j by A10,A11,WAYBEL_3:28;
      end;
      hence f <= g by WAYBEL_3:28;
    end;
    then
A12: f <= inf X by A2,YELLOW_0:33;
    f.i = a by A9,FUNCT_7:31;
    hence (inf X).i >= a by A12,WAYBEL_3:28;
  end;
  J.i is complete LATTICE by A1;
  hence thesis by A4,A7,YELLOW_0:33;
end;
