
theorem Th23: :: 1.4. THEOREM, (3+) => (1), p. 180
  for S being complete LATTICE for T being complete continuous LATTICE
  for g being infs-preserving Function of S,T
  st LowerAdj g is waybelow-preserving holds g is directed-sups-preserving
proof
  let S be complete LATTICE;
  let T be complete continuous LATTICE;
  let g be infs-preserving Function of S,T such that
A1: for t,t9 being Element of T st t << t9
  holds (LowerAdj g).t << (LowerAdj g).t9;
  let D be Subset of S;
  assume
A2: D is non empty directed;
  assume ex_sup_of D,S;
  thus ex_sup_of g.:D, T by YELLOW_0:17;
A3: sup (g.:D) <= g.sup D by WAYBEL17:15;
A4: g.sup D = sup waybelow (g.sup D) by WAYBEL_3:def 5;
  waybelow (g.sup D) is_<=_than sup (g.:D)
  proof
    let t be Element of T;
    assume t in waybelow (g.sup D);
    then t << g.sup D by WAYBEL_3:7;
    then
A5: (LowerAdj g).t << (LowerAdj g).(g.sup D) by A1;
A6: [g, LowerAdj g] is Galois by Def1;
    then
A7: (LowerAdj g)*g <= id S by WAYBEL_1:18;
    (id S).sup D = sup D by FUNCT_1:18;
    then ((LowerAdj g)*g).sup D <= sup D by A7,YELLOW_2:9;
    then (LowerAdj g).(g.sup D) <= sup D by FUNCT_2:15;
    then consider x being Element of S such that
A8: x in D and
A9: (LowerAdj g).t <= x by A2,A5;
A10: g.x in g.:D by A8,FUNCT_2:35;
A11: t <= g.x by A6,A9,WAYBEL_1:8;
    g.x <= sup (g.:D) by A10,YELLOW_2:22;
    hence thesis by A11,ORDERS_2:3;
  end;
  then g.sup D <= sup (g.:D) by A4,YELLOW_0:32;
  hence thesis by A3,ORDERS_2:2;
end;
