reserve m for Cardinal,
  A,B,C for Ordinal,
  x,y,z,X,Y,Z,W for set,
  f for Function;
reserve f,g for Function,
  L for Sequence,
  F for Cardinal-Function;

theorem Th24:
  dom L is limit_ordinal & (for A st A in dom L holds L.A = Rank A
  ) implies Rank dom L = Union L
proof
  assume that
A1: dom L is limit_ordinal and
A2: for A st A in dom L holds L.A = Rank A;
A3: union rng L = Union L by CARD_3:def 4;
  now
    assume
A4: dom L <> {};
    thus Rank dom L c= Union L
    proof
      let x be object;
      assume x in Rank dom L;
      then consider A such that
A5:   A in dom L and
A6:   x in Rank A by A1,A4,CLASSES1:31;
      L.A = Rank A by A2,A5;
      then Rank A in rng L by A5,FUNCT_1:def 3;
      hence thesis by A3,A6,TARSKI:def 4;
    end;
    thus Union L c= Rank dom L
    proof
      let x be object;
      assume x in Union L;
      then consider X such that
A7:   x in X and
A8:   X in rng L by A3,TARSKI:def 4;
      consider y being object such that
A9:   y in dom L and
A10:  X = L.y by A8,FUNCT_1:def 3;
      reconsider y as Ordinal by A9;
      X = Rank y by A2,A9,A10;
      hence thesis by A1,A7,A9,CLASSES1:31;
    end;
  end;
  hence thesis by A3,CLASSES1:29,RELAT_1:42,ZFMISC_1:2;
end;
