reserve i, x, I for set,
  A, B, M for ManySortedSet of I,
  f, f1 for Function;
reserve SF, SG for SubsetFamily of M;
reserve E, T for Element of Bool M;

theorem Th24: :: MSSUBFAM:4
  for Z being ManySortedSubset of M st for Z1 being ManySortedSet
  of I st Z1 in SF holds Z c=' Z1 holds Z c=' meet |:SF:|
proof
  let Z be ManySortedSubset of M such that
A1: for Z1 be ManySortedSet of I st Z1 in SF holds Z c=' Z1;
  let i be object such that
A2: i in I;
  consider Q being Subset-Family of M.i such that
A3: Q = |:SF:|.i and
A4: (meet |:SF:|).i = Intersect Q by A2,MSSUBFAM:def 1;
A5: now
    let q be set such that
A6: q in Q;
    per cases;
    suppose
      SF is non empty;
      then |:SF:|.i = { x.i where x is Element of Bool M : x in SF } by A2,Th14
;
      then consider a being Element of Bool M such that
A7:   q = a.i and
A8:   a in SF by A3,A6;
      Z c=' a by A1,A8;
      hence Z.i c= q by A2,A7;
    end;
    suppose
      SF is empty;
      then |:SF:| = EmptyMS I;
      hence Z.i c= q by A3,A6;
    end;
  end;
  Z c= M by PBOOLE:def 18;
  then Z.i is Subset of M.i by A2;
  hence thesis by A4,A5,MSSUBFAM:4;
end;
