reserve x,X,X2,Y,Y2 for set;
reserve GX for non empty TopSpace;
reserve A2,B2 for Subset of GX;
reserve B for Subset of GX;

theorem
  for Fu being Subset-Family of GX st (for A being Subset of GX st A in
  Fu holds A is a_union_of_components of GX) holds meet Fu is
  a_union_of_components of GX
proof
  let Fu be Subset-Family of GX;
  assume
A1: for A being Subset of GX st A in Fu holds A is a_union_of_components of GX;
  now
    per cases;
    case
A2:   Fu<>{};
      {B:B is a_component & for A2 st A2 in Fu holds B c= A2} c=
      bool(the carrier of GX)
      proof
        let x be object;
        assume
        x in {B:B is a_component & for A2 st A2 in Fu holds B c= A2};
        then
        ex B st x=B & B is a_component & for A2 st A2 in Fu holds B
        c= A2;
        hence thesis;
      end;
      then reconsider
      F1={B:B is a_component & for A2 st A2 in Fu holds B c=
      A2} as Subset-Family of GX;
A3:   meet Fu c= union F1
      proof
        let x be object;
        consider Y2 being object such that
A4:     Y2 in Fu by A2,XBOOLE_0:def 1;
        reconsider Y2 as set by TARSKI:1;
        reconsider B2=Y2 as Subset of GX by A4;
        B2 is a_union_of_components of GX by A1,A4;
        then consider F being Subset-Family of GX such that
A5:     for B being Subset of GX st B in F holds B is a_component and
A6:     B2=union F by Def2;
        assume
A7:     x in meet Fu;
        then x in Y2 by A4,SETFAM_1:def 1;
        then consider Y3 being set such that
A8:     x in Y3 and
A9:     Y3 in F by A6,TARSKI:def 4;
        reconsider B3=Y3 as Subset of GX by A9;
A10:    for A2 st A2 in Fu holds B3 c= A2
        proof
          reconsider p=x as Point of GX by A7;
          let A2;
          assume
A11:      A2 in Fu;
          then x in A2 by A7,SETFAM_1:def 1;
          then Component_of p c= A2 by A1,A11,Th21;
          hence thesis by A5,A8,A9,CONNSP_1:41;
        end;
        B3 is a_component by A5,A9;
        then Y3 in F1 by A10;
        hence thesis by A8,TARSKI:def 4;
      end;
A12:  for B being Subset of GX st B in F1 holds B is a_component
      proof
        let B be Subset of GX;
        assume B in F1;
        then ex B1 be Subset of GX st B=B1 & B1 is a_component & for A2
        st A2 in Fu holds B1 c= A2;
        hence thesis;
      end;
      union F1 c= meet Fu
      proof
        let x be object;
        assume x in union F1;
        then consider X such that
A13:    x in X and
A14:    X in F1 by TARSKI:def 4;
        consider B such that
A15:    X=B and
        B is a_component and
A16:    for A2 st A2 in Fu holds B c= A2 by A14;
        for Y st Y in Fu holds x in Y
        proof
          let Y;
          assume Y in Fu;
          then B c= Y by A16;
          hence thesis by A13,A15;
        end;
        hence thesis by A2,SETFAM_1:def 1;
      end;
      then meet Fu=union F1 by A3;
      hence thesis by A12,Def2;
    end;
    case
      Fu={};
      then meet Fu={}(GX) by SETFAM_1:def 1;
      hence thesis by Th19;
    end;
  end;
  hence thesis;
end;
