reserve x,y,z for object,X,Y for set;
reserve N for e_net;

theorem Th24:
  ((the escape of N) \ id the carrier of N) *
    ((the escape of N) \ id the carrier of N) = {} &
  ((the entrance of N) \ id the carrier of N) *
    ((the entrance of N) \ id the carrier of N) = {} &
  ((the escape of N) \ id(the carrier of N)) *
    ((the entrance of N) \ id the carrier of N) = {} &
  ((the entrance of N) \ id the carrier of N) *
    ((the escape of N) \ id the carrier of N) = {}
proof
  set T = the entrance of N, C = the carrier of N;
  set E = the escape of N, I = id C;
  (T \ I) * (T \ I) c= T * (T \ I) by RELAT_1:30,XBOOLE_1:36; then
A1: (T \ I) * (T \ I) c= {} by Def2;
  (E \ I) * (T \ I) c= E * (T \ I) by RELAT_1:30,XBOOLE_1:36;
  then
A2: (E \ I) * (T \ I) c= {} by Th15;
  (T \ I) * (E \ I) c= T * (E \ I) by RELAT_1:30,XBOOLE_1:36; then
A3: (T \ I) * (E \ I) c= {} by Th15;
  (E \ I) * (E \ I) c= E * (E \ I) by RELAT_1:30,XBOOLE_1:36; then
  (E \ I) * (E \ I) c= {} by Def2;
  hence thesis by A1,A2,A3,XBOOLE_1:3;
end;
