reserve x for Real,

  Z for open Subset of REAL;

theorem
  Z c= dom (cos*cot) implies cos*cot is_differentiable_on Z & for x st x
  in Z holds ((cos*cot)`|Z).x =sin(cot.x)/(sin.x)^2
proof
  assume
A1: Z c= dom (cos*cot);
A2: for x st x in Z holds sin.x<>0
  proof
    let x;
    assume x in Z;
    then x in dom (cos/sin) by A1,FUNCT_1:11;
    hence thesis by FDIFF_8:2;
  end;
A3: for x st x in Z holds cos*cot is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then sin.x<>0 by A2;
    then
A4: cot is_differentiable_in x by FDIFF_7:47;
    cos is_differentiable_in cot.x by SIN_COS:63;
    hence thesis by A4,FDIFF_2:13;
  end;
  then
A5: cos*cot is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((cos*cot)`|Z).x =sin(cot.x)/(sin.x)^2
  proof
    let x;
A6: cos is_differentiable_in cot.x by SIN_COS:63;
    assume
A7: x in Z;
    then
A8: sin.x<>0 by A2;
    then cot is_differentiable_in x by FDIFF_7:47;
    then diff(cos*cot,x) = diff(cos,cot.x)*diff(cot,x) by A6,FDIFF_2:13
      .=(-sin(cot.x))*diff(cot,x) by SIN_COS:63
      .=(-sin(cot.x)) * (-1/(sin.x)^2) by A8,FDIFF_7:47
      .=sin(cot.x)/(sin.x)^2;
    hence thesis by A5,A7,FDIFF_1:def 7;
  end;
  hence thesis by A1,A3,FDIFF_1:9;
end;
