reserve Omega for non empty set;
reserve Sigma for SigmaField of Omega;
reserve S for non empty Subset of REAL;
reserve r for Real;
reserve T for Nat;
reserve I for TheEvent of r;

theorem Th1:
 for MyFunc be Filtration of S,Sigma,
     t2 being Element of [.0,+infty.] holds
     ex q being random_variable of Sigma,ExtBorelsubsets st
      q=Omega-->t2 & q is_StoppingTime_wrt MyFunc,S
proof
 let MyFunc be Filtration of S,Sigma;
 let t2 be Element of [.0,+infty.];
  Fin1: for t being Element of S holds
  {w where w is Element of Omega: (Omega-->t2).w<=t} in MyFunc.t
  proof
   let t be Element of S;
   reconsider MyFt = MyFunc.t as SigmaField of Omega by KOLMOG01:def 2;
   set R = {w where w is Element of Omega: (Omega-->t2).w<=t};
H1: for x being object st x in R holds x in Omega
    proof
     let x be object;
     assume x in R;
     then ex w3 being Element of Omega st w3=x & (Omega-->t2).w3<=t;
     hence thesis;
    end;
   per cases;
   suppose S1: t2<=t;
   R = Omega
   proof
    for x being object st x in Omega holds x in R
    proof
     let x be object;
     assume x in Omega; then
     reconsider x as Element of Omega;
     (Omega-->t2).x=t2 by FUNCOP_1:7;
     hence thesis by S1;
    end;
    hence thesis by H1,TARSKI:2;
   end; then
   R in MyFt by PROB_1:5;
   hence thesis;
   end;
   suppose S1: t2>t;
    R c= {}
    proof
     let x be object;
     assume x in R;
     then ex w3 being Element of Omega st w3=x & (Omega-->t2).w3<=t;
    hence thesis by S1,FUNCOP_1:7;
    end;
   then R={}; then
   R in MyFt by PROB_1:4;
   hence thesis;
   end;
 end;
  set OC=Omega-->t2;
  OC is random_variable of Sigma,ExtBorelsubsets by FINANCE3:10;
  then reconsider OC as random_variable of Sigma,ExtBorelsubsets;
  OC is_StoppingTime_wrt MyFunc,S by Fin1;
  hence thesis;
end;
