
theorem Th24:
  for T being non empty TopSpace,A being Subset of T holds A is
  closed implies for S being sequence of T st rng S c= A holds Lim S c= A
proof
  let T be non empty TopSpace,A be Subset of T;
  assume
A1: A is closed;
  let S be sequence of T such that
A2: rng S c= A;
  thus Lim S c= A
  proof
    reconsider A as Subset of T;
    reconsider L = Lim S as Subset of T;
    L c= A
    proof
      let y be object;
      assume
A3:   y in L;
      then reconsider p=y as Point of T;
A4:   S is_convergent_to p by A3,Def5;
      for U1 being Subset of T st U1 is open holds p in U1 implies A meets U1
      proof
        let U1 be Subset of T;
        assume
A5:     U1 is open;
        reconsider U2 = U1 as Subset of T;
        assume p in U1;
        then consider n being Nat such that
A6:     for m being Nat st n <= m holds S.m in U2 by A4,A5;
A7: n in NAT by ORDINAL1:def 12;
        dom S = NAT by FUNCT_2:def 1;
        then
A8:     S.n in rng S by FUNCT_1:def 3,A7;
        S.n in U1 by A6;
        then S.n in A /\ U1 by A2,A8,XBOOLE_0:def 4;
        hence thesis;
      end;
      then p in Cl A by PRE_TOPC:def 7;
      hence thesis by A1,PRE_TOPC:22;
    end;
    hence thesis;
  end;
end;
