reserve x, y, X for set;
reserve E for non empty set;
reserve e for Element of E;
reserve u, u1, v, v1, v2, w, w9, w1, w2 for Element of E^omega;
reserve F for Subset of E^omega;
reserve i, k, l for Nat;
reserve TS for non empty transition-system over F;
reserve S, T for Subset of TS;
reserve SA for non empty semiautomaton over F;
reserve A for non empty automaton over F;
reserve p, q for Element of A;
reserve TS for non empty transition-system over Lex(E) \/ {<%>E};

theorem Th24:
  for R being RedSequence of ==>.-relation(TS) st (R.1)`2 = u^v &
  (R.len R)`2 = <%>E ex l st l in dom R & (R.l)`2 = v
proof
  defpred P[Nat] means for R being RedSequence of ==>.-relation(TS), u st len
  R = $1 & (R.1)`2 = u^v & (R.len R)`2 = <%>E ex l st l in dom R & (R.l)`2 = v;
A1: now
    let i;
    assume
A2: P[i];
    thus P[i + 1]
    proof
      let R be RedSequence of ==>.-relation(TS), u such that
A3:   len R = i + 1 and
A4:   (R.1)`2 = u^v and
A5:   (R.len R)`2 = <%>E;
      per cases;
      suppose
A6:     len u = 0;
        set j = 1;
        take j;
        rng R <> {};
        hence j in dom R by FINSEQ_3:32;
        u = {} by A6;
        hence (R.j)`2 = v by A4;
      end;
      suppose
A7:     len u > 0;
        then consider e, u1 such that
A8:     u = <%e%>^u1 by Th7;
        len u >= 0 + 1 by A7,NAT_1:13;
        then len u + len v >= 1 + len v by XREAL_1:6;
        then len(u^v) >= 1 + len v by AFINSQ_1:17;
        then len(u^v) >= 1 by Th1;
        then len R + len(u^v) > len(u^v) + 1 by A4,A5,Th23,XREAL_1:8;
        then len R > 1 by XREAL_1:6;
        then consider R9 being RedSequence of ==>.-relation(TS) such that
A9:     len R9 + 1 = len R and
A10:    for k st k in dom R9 holds R9.k = R.(k + 1) by REWRITE3:7;
A11:    rng R9 <> {};
        then
A12:    (R9.1)`2 = (R.(1 + 1))`2 by A10,FINSEQ_3:32;
        1 in dom R9 by A11,FINSEQ_3:32;
        then 1 <= len R9 by FINSEQ_3:25;
        then len R9 in dom R9 by FINSEQ_3:25;
        then
A13:    (R9.len R9)`2 = <%>E by A5,A9,A10;
A14:    (R.1)`2 = <%e%>^(u1^v) by A4,A8,AFINSQ_1:27;
        thus ex k st k in dom R & (R.k)`2 = v
        proof
          per cases by A4,A5,A14,Th22;
          suppose
            (R.2)`2 = u^v;
            then consider l such that
A15:        l in dom R9 and
A16:        (R9.l)`2 = v by A2,A3,A9,A12,A13;
            set k = l + 1;
            take k;
            thus k in dom R by A9,A15,Th3;
            thus (R.k)`2 = v by A10,A15,A16;
          end;
          suppose
            (R.2)`2 = u1^v;
            then consider l such that
A17:        l in dom R9 and
A18:        (R9.l)`2 = v by A2,A3,A9,A12,A13;
            set k = l + 1;
            take k;
            thus k in dom R by A9,A17,Th3;
            thus (R.k)`2 = v by A10,A17,A18;
          end;
        end;
      end;
    end;
  end;
A19: P[0];
  for k holds P[k] from NAT_1:sch 2(A19, A1);
  hence thesis;
end;
