 reserve a,b,c,x for Real;
 reserve C for non empty set;

theorem LemGlue:
  for f,g being PartFunc of REAL, REAL st
  f is continuous non empty & g is continuous non empty &
  (ex a,b,c being Real st dom f = [.a,b.] & dom g = [.b,c.]) &
  f tolerates g
    ex h being PartFunc of REAL, REAL st
    h = f +* g & for x being Real st x in dom h holds h is_continuous_in x
  proof
    let f,g be PartFunc of REAL, REAL;
    assume
A1: f is continuous non empty & g is continuous non empty &
    (ex a,b,c being Real st dom f = [.a,b.] & dom g = [.b,c.]) &
    f tolerates g;
    reconsider ff = f, gg = g as non empty continuous PartFunc of REAL, REAL
      by A1;
    consider a,b,c being Real such that
AB: dom f = [.a,b.] & dom g = [.b,c.] by A1;
    dom ff <> {} & dom gg <> {}; then
Ab: a <= b & b <= c by XXREAL_1:29,AB;
AA: dom f /\ dom g = {b} by XXREAL_1:418,Ab,AB;
    reconsider h = f +* g as PartFunc of REAL, REAL;
    take h;
    thus h = f +* g;
    let x be Real;
J2: h | dom f = (g +* f) | dom f by FUNCT_4:34,A1
       .= f;
    assume
JJ: x in dom h; then
    per cases by FUNCT_4:12;
    suppose
J1: x in dom f;
    set hf = h |dom f;
    set hg = h |dom g;
    for r being Real st 0 < r
     ex s being Real st 0 < s &
    for x1 being Real st x1 in dom h & |.x1-x.| < s holds |.h.x1-h.x.| < r
    proof
      let r be Real;
      dom f c= dom h & dom g c= dom h by FUNCT_4:10; then
XX:   dom hf = dom f & dom hg = dom g by RELAT_1:62;
SF:   x in dom hf by RELAT_1:57,J1,JJ;
      assume
R0:   0 < r; then
      consider s2 being Real such that
SB:   0 < s2 & for x1 being Real st x1 in dom hf & |.x1-x.|<s2 holds
        |.hf.x1-hf.x.| < r/2 by J1,J2,A1,FCONT_1:3;
KK:   b in dom f /\ dom g by AA,TARSKI:def 1; then
KA:   b in dom f & b in dom g by XBOOLE_0:def 4;
KI:   b in dom hf & b in dom hg by XX,XBOOLE_0:def 4,KK;
      consider s1 being Real such that
Sb:   0 < s1 & for x1 being Real st x1 in dom hg & |.x1-b.|<s1 holds
        |.hg.x1-hg.b.| < r/2 by FCONT_1:3,R0,A1,KA;
      take s = min (s2,s1);
      thus 0 < s by SB,Sb,XXREAL_0:15;
SS:   r/2 < r by XREAL_1:216,R0;
        let x1 be Real;
        assume
SC:     x1 in dom h & |.x1-x.| < s;
        s <= s2 by XXREAL_0:17; then
H1:     |.x1-x.| < s2 by XXREAL_0:2,SC;
        per cases by FUNCT_4:12,SC;
        suppose
ZT:       x1 in dom f; then
I1:       x1 in dom hf by RELAT_1:57,SC;
SD:       |.hf.x1-hf.x.| < r / 2 by SB,ZT,H1,RELAT_1:57,SC;
s1:       hf.x1 = h.x1 by FUNCT_1:47,I1;
          |.h.x1-h.x.| < r / 2 by SD,s1,FUNCT_1:47,SF;
          hence thesis by SS,XXREAL_0:2;
        end;
        suppose
P1:       x1 in dom g; then
          x1 in dom hg; then
P2:       h.x1 = hg.x1 by FUNCT_1:47;
P3:       h.x = hf.x by FUNCT_1:47,SF;
          s <= s1 by XXREAL_0:17; then
P6:       |.x1-x.| < s1 by XXREAL_0:2,SC;
WA:       hg.b = hf.b by J2,KK,A1,PARTFUN1:def 4;
M3:       x + 0 <= b by XXREAL_1:1,J1,AB;
M7:       b <= x1 & x1 <= c by XXREAL_1:1,P1,AB;
m0:       x + 0 <= x1 by M7,XXREAL_0:2,M3;
          b + 0 <= x1 by XXREAL_1:1,P1,AB; then
M1:       |.x1 - b.| = x1 - b by ABSVALUE:def 1,XREAL_1:19;
M2:       |.b - x.| = b - x by ABSVALUE:def 1,M3,XREAL_1:19;
M8:       |.x1 - x.| = |.x1-b.| + |.b-x.|
            by M1,M2,m0,ABSVALUE:def 1,XREAL_1:19; then
          |.x1-b.| <= |.x1 - x.| by COMPLEX1:46,XREAL_1:31; then
          |.x1-b.| < s1 by P6,XXREAL_0:2; then
KJ:       |.hg.x1-hg.b.| < r / 2 by Sb,P1;
          |.b-x.| <= |.x1 - x.| by M8,XREAL_1:31,COMPLEX1:46; then
          |.b - x.| < s2 by H1,XXREAL_0:2; then
          |.hf.b-hf.x.| < r / 2 by SB,KI; then
WW:       |.hg.x1-hg.b.| + |.hf.b-hf.x.| < r / 2 + r / 2 by KJ,XREAL_1:8;
          |.hg.x1-hf.x.| <= |.hg.x1-hg.b.| + |.hg.b-hf.x.| by COMPLEX1:63;
          hence thesis by P2,P3,WA,XXREAL_0:2,WW;
      end;
    end;
    hence thesis by FCONT_1:3;
    end;
    suppose
J1: x in dom g;
    for r being Real st 0<r ex s being Real st 0<s &
    for x1 being Real st x1 in dom h & |.x1-x.|<s holds |.h.x1-h.x.| < r
    proof
      let r be Real;
      set hf = h |dom f;
      set hg = h |dom g;
      dom f c= dom h & dom g c= dom h by FUNCT_4:10; then
XX:   dom hf = dom f & dom hg = dom g by RELAT_1:62;
SF:   x in dom hg by J1;
      assume
R0:   0 < r; then
      consider s2 being Real such that
SB:   0 < s2 & for x1 being Real st x1 in dom hg & |.x1-x.|<s2 holds
        |.hg.x1-hg.x.| < r/2 by J1,FCONT_1:3,A1;
KK:   b in dom f /\ dom g by AA,TARSKI:def 1; then
KA:   b in dom f & b in dom g by XBOOLE_0:def 4;
KI:   b in dom hf & b in dom hg by XX,KK,XBOOLE_0:def 4;
      consider s1 being Real such that
Sb:   0 < s1 & for x1 being Real st x1 in dom hf & |.x1-b.|<s1 holds
        |.hf.x1-hf.b.| < r/2 by FCONT_1:3,R0,J2,A1,KA;
      take s = min (s2,s1);
      thus 0 < s by SB,Sb,XXREAL_0:15;
SS:   r/2 < r by XREAL_1:216,R0;
        let x1 be Real;
        assume
SC:     x1 in dom h & |.x1-x.| < s;
        s <= s2 by XXREAL_0:17; then
H1:     |.x1-x.| < s2 by XXREAL_0:2,SC;
        per cases by FUNCT_4:12,SC;
        suppose
ZT:       x1 in dom g; then
I1:       x1 in dom hg;
SD:       |.hg.x1 - hg.x.| < r / 2 by SB,ZT,H1;
s1:       hg.x1 = h.x1 by FUNCT_1:47,I1;
          |.h.x1-h.x.| < r / 2 by SD,s1,FUNCT_1:47,SF;
          hence thesis by SS,XXREAL_0:2;
        end;
        suppose
P1:       x1 in dom f; then
          x1 in dom hf by RELAT_1:57,SC; then
P2:       h.x1 = hf.x1 by FUNCT_1:47;
P3:       h.x = hg.x by FUNCT_1:47,SF;
          s <= s1 by XXREAL_0:17; then
          |.x1 - x.| < s1 by XXREAL_0:2,SC; then
P6:       |.x - x1.| < s1 by COMPLEX1:60;
WA:       hg.b = hf.b by J2,KK,A1,PARTFUN1:def 4;
M3:       x - 0 >= b by XXREAL_1:1,J1,AB;
M7:       a <= x1 & x1 <= b by XXREAL_1:1,P1,AB;
m0:       x1 + 0 <= x by M7,XXREAL_0:2,M3;
          b - 0 >= x1 by XXREAL_1:1,P1,AB; then
M1:       |.b - x1.| = b - x1 by ABSVALUE:def 1,XREAL_1:11;
M2:       |.x - b.| = x - b by ABSVALUE:def 1,M3,XREAL_1:11;
M8:       |.x - x1.| = |.b-x1.| + |.x-b.|
            by M1,M2,m0,ABSVALUE:def 1,XREAL_1:19; then
          |.b - x1.| <= |.x - x1.| by COMPLEX1:46,XREAL_1:31; then
          |.b - x1.| < s1 by P6,XXREAL_0:2; then
          |.x1 - b.| < s1 by COMPLEX1:60; then
KJ:       |.hf.x1 - hf.b.| < r / 2 by Sb,P1,RELAT_1:57,SC;
LK:       |.b - x.| = |.x - b.| by COMPLEX1:60;
          |.x - b.| <= |.x - x1.| by M8,XREAL_1:31,COMPLEX1:46; then
          |.b - x.| <= |.x1 - x.| by COMPLEX1:60,LK; then
          |.b - x.| < s2 by H1,XXREAL_0:2; then
          |.hg.b - hg.x.| < r / 2 by SB,KI; then
WW:       |.hf.x1 - hf.b.| + |.hg.b - hg.x.| < r / 2 + r / 2
            by KJ,XREAL_1:8;
          |.hf.x1-hg.x.| <= |.hf.x1-hf.b.| + |.hf.b-hg.x.| by COMPLEX1:63;
          hence thesis by P2,P3,WA,XXREAL_0:2,WW;
        end;
      end;
      hence thesis by FCONT_1:3;
    end;
  end;
