reserve i, j, n for Nat,
  f for non constant standard special_circular_sequence,
  g for clockwise_oriented non constant standard special_circular_sequence,
  p, q for Point of TOP-REAL 2,
  P for Subset of TOP-REAL 2,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board;
reserve f for clockwise_oriented non constant standard
  special_circular_sequence;

theorem Th24:
  p in RightComp f implies E-bound L~f > p`1
proof
  set g = Rotate(f,N-min L~f);
A1: L~f = L~g by REVROT_1:33;
  reconsider u = p as Point of Euclid 2 by EUCLID:22;
  assume p in RightComp f;
  then p in RightComp g by REVROT_1:37;
  then u in Int RightComp g by TOPS_1:23;
  then consider r being Real such that
A2: r > 0 and
A3: Ball(u,r) c= RightComp g by GOBOARD6:5;
  reconsider r as Real;
  reconsider k = |[p`1+r/2,p`2]| as Point of Euclid 2 by EUCLID:22;
  dist(u,k) = (Pitag_dist 2).(u,k) by METRIC_1:def 1
    .= sqrt ((p`1 - |[p`1+r/2,p`2]|`1)^2 + (p`2 - |[p`1+r/2,p`2]|`2)^2) by
TOPREAL3:7
    .= sqrt ((p`1 - (p`1+r/2))^2 + (p`2 - |[p`1+r/2,p`2]|`2)^2)
    .= sqrt ((p`1 - (p`1+r/2))^2 + (p`2 - p`2)^2)
    .= sqrt ((r/2)^2)
    .= r/2 by A2,SQUARE_1:22;
  then dist(u,k) < r/1 by A2,XREAL_1:76;
  then
A4: k in Ball(u,r) by METRIC_1:11;
  RightComp g misses LeftComp g by Th14;
  then
A5: not |[p`1+r/2,p`2]| in LeftComp g by A3,A4,XBOOLE_0:3;
  set x = |[p`1+r/2,N-bound L~SpStSeq L~g]|;
A6: LSeg(NW-corner L~g,NE-corner L~g) c= L~SpStSeq L~g by SPRECT_3:14;
A7: proj1.x = x`1 by PSCOMP_1:def 5
    .= p`1+r/2;
  N-min L~f in rng f by SPRECT_2:39;
  then
A8: g/.1 = N-min L~g by A1,FINSEQ_6:92;
  then |[p`1+r/2,p`2]|`1 <= E-bound L~g by A5,JORDAN2C:111;
  then p`1+r/2 <= E-bound L~g;
  then
A9: x`1 <= E-bound L~g;
A10: x`2 = N-bound L~g by SPRECT_1:60;
  |[p`1+r/2,p`2]|`1 >= W-bound L~g by A8,A5,JORDAN2C:110;
  then p`1+r/2 >= W-bound L~g;
  then
A11: x`1 >= W-bound L~g;
  LSeg(NW-corner L~g, NE-corner L~g) = { q : q`1 <= E-bound L~g & q`1 >=
  W-bound L~g & q`2 = N-bound L~g} by SPRECT_1:25;
  then x in LSeg(NW-corner L~g,NE-corner L~g) by A9,A11,A10;
  then
  proj1.:L~SpStSeq L~g is bounded_above & p`1+r/2 in proj1.:L~SpStSeq L~g
  by A6,A7,FUNCT_2:35;
  then
A12: upper_bound(proj1.:L~SpStSeq L~g) >= p`1+r/2 by SEQ_4:def 1;
  r/2 > 0 by A2,XREAL_1:139;
  then
A13: p`1+r/2 > p`1+0 by XREAL_1:6;
  E-bound L~SpStSeq L~g = E-bound L~g &
   E-bound L~SpStSeq L~g = upper_bound(proj1
  .:L~ SpStSeq L~g) by SPRECT_1:46,61;
  hence thesis by A1,A12,A13,XXREAL_0:2;
end;
