reserve F,G for Group;
reserve G1 for Subgroup of G;
reserve Gc for cyclic Group;
reserve H for Subgroup of Gc;
reserve f for Homomorphism of G,Gc;
reserve a,b for Element of G;
reserve g for Element of Gc;
reserve a1 for Element of G1;
reserve k,m,n,p,s for Element of NAT;
reserve i0,i,i1,i2 for Integer;
reserve j,j1 for Element of INT.Group;
reserve x,y,t for set;

theorem Th24:
  for Gc being strict finite cyclic Group st (ex k st card Gc = 2*
  k) holds ex g1 being Element of Gc st ord g1 = 2 & for g2 being Element of Gc
  st ord g2 = 2 holds g1=g2
proof
  let Gc be strict finite cyclic Group;
  set n = card Gc;
  given k such that
A1: n=2*k;
  consider g being Element of Gc such that
A2: Gc=gr{g} by GR_CY_1:def 7;
A3: ord g = n by A2,GR_CY_1:7;
  take g|^k;
A4: g|^k|^2=g|^card Gc by A1,GROUP_1:35
    .= 1_Gc by GR_CY_1:9;
A5: k<>0 by A1;
A6: for p being Nat st g|^k|^ p = 1_Gc & p <> 0 holds 2 <= p
  proof
    let p be Nat;
    assume that
A7: g|^k|^p=1_Gc and
A8: p<>0 & 2>p;
A9: g is not being_of_order_0 & 1_Gc = g|^(k*p) by A7,GROUP_1:35,GR_CY_1:6;
    n>k*p & k*p<>0 by A1,A5,A8,XCMPLX_1:6,XREAL_1:68;
    hence contradiction by A3,A9,GROUP_1:def 11;
  end;
  g|^k is not being_of_order_0 by GR_CY_1:6;
  hence ord(g|^k) = 2 by A4,A6,GROUP_1:def 11;
  let g2 be Element of Gc;
  consider k1 being Element of NAT such that
A10: g2=g|^k1 by A2,Th6;
  assume that
A11: ord g2=2 and
A12: g|^k<>g2;
  now
A13: g is not being_of_order_0 by GR_CY_1:6;
    consider t,t1 being Nat such that
A14: k1=(k*t)+t1 and
A15: t1<k by A5,NAT_1:17;
A16: 2*t1<n by A1,A15,XREAL_1:68;
    t1<>0
    proof
      assume t1=0;
      then
A17:  g|^k1=g|^(k*( 2*(t div 2)+(t mod 2) )) by A14,NAT_D:2
        .=g|^( k* 2*(t div 2)+ k*(t mod 2) )
        .=g|^( k* 2*(t div 2) )*(g|^( k*(t mod 2))) by GROUP_1:33
        .=g|^( k* 2)|^(t div 2) *(g|^ (k*(t mod 2))) by GROUP_1:35
        .=(1_Gc)|^(t div 2) *(g|^ (k*(t mod 2))) by A4,GROUP_1:35
        .=(1_Gc) *(g|^ (k*(t mod 2))) by GROUP_1:31
        .=(g|^(k*(t mod 2))) by GROUP_1:def 4;
      per cases by NAT_D:12;
      suppose
        t mod 2 = 0;
        then g|^k1 = 1_Gc by A17,GROUP_1:25;
        hence contradiction by A11,A10,GROUP_1:42;
      end;
      suppose
        t mod 2 = 1;
        hence contradiction by A12,A10,A17;
      end;
    end;
    then
A18: 2*t1<>0;
    1_Gc=g|^k1|^2 by A11,A10,GROUP_1:41
      .=g|^(((k*t)+t1)*2) by A14,GROUP_1:35
      .=g|^(n*t+t1*2) by A1
      .=g|^(n*t)*(g|^(t1*2)) by GROUP_1:33
      .=g|^(ord g)|^t*(g|^(t1*2)) by A3,GROUP_1:35
      .=(1_Gc)|^t*(g|^(t1*2)) by GROUP_1:41
      .=1_Gc*(g|^(t1*2)) by GROUP_1:31
      .=g|^(2*t1) by GROUP_1:def 4;
    hence contradiction by A3,A18,A16,A13,GROUP_1:def 11;
  end;
  hence thesis;
end;
