 reserve a,x for Real;
 reserve n for Nat;
 reserve A for non empty closed_interval Subset of REAL;
 reserve f,f1 for PartFunc of REAL,REAL;
 reserve Z for open Subset of REAL;

theorem
A c= Z & Z c= dom (ln*cosec) & Z = dom cot & (-cot)|A is continuous
implies integral((-cot),A)=(ln*cosec).(upper_bound A)-
(ln*cosec).(lower_bound A)
proof
  assume
A1:A c= Z & Z c= dom (ln*cosec) & Z = dom cot & (-cot)|A is continuous;
then A2:Z = dom (-cot) by VALUED_1:8;
    then
A3:(-cot) is_integrable_on A & (-cot)|A is bounded by A1,INTEGRA5:10,11;
A4:ln*cosec is_differentiable_on Z by A1,FDIFF_9:19;
A5:for x st x in Z holds sin.x<>0
  proof
    let x;
    assume x in Z;
    then x in dom cosec by A1,FUNCT_1:11;
    hence thesis by RFUNCT_1:3;
  end;
A6:for x being Element of REAL
    st x in dom ((ln*cosec)`|Z) holds ((ln*cosec)`|Z).x = (-cot).x
   proof
     let x be Element of REAL;
     assume x in dom ((ln*cosec)`|Z);then
A7:  x in Z by A4,FDIFF_1:def 7;then
A8:  sin.x<>0 by A5;
     ((ln*cosec)`|Z).x = -cot(x) by A1,A7,FDIFF_9:19
                 .=-cot.x by A8,SIN_COS9:16
                 .=(-cot).x by VALUED_1:8;
     hence thesis;
   end;
  dom ((ln*cosec)`|Z)=dom (-cot) by A2,A4,FDIFF_1:def 7;
  then ((ln*cosec)`|Z)= -cot by A6,PARTFUN1:5;
  hence thesis by A1,A3,A4,INTEGRA5:13;
end;
