
theorem Th24:
  for f be FinSequence of TOP-REAL 2, i, j be Nat st f is being_S-Seq &
   1 <= i & i <= j & j <= len f holds LE f/.i, f/.j, L~f, f/.1, f/.len f
proof
  let f be FinSequence of TOP-REAL 2, i, j be Nat such that
A1: f is being_S-Seq and
A2: 1 <= i and
A3: i <= j and
A4: j <= len f;
  consider k being Nat such that
A5: i+k = j by A3,NAT_1:10;
A6: len f >= 2 by A1,TOPREAL1:def 8;
  then reconsider P = L~f as non empty Subset of TOP-REAL 2 by TOPREAL1:23;
  defpred ILE[Nat] means 1 <= i & i+$1 <= len f implies LE f/.i, f
  /.(i+$1), P, f/.1, f/.len f;
A7: for l be Nat st ILE[l] holds ILE[l + 1]
  proof
    let l be Nat;
    assume
A8: ILE[l];
A9: i+l <= i+l+1 by NAT_1:11;
    assume that
A10: 1 <= i and
A11: i+(l+1) <= len f;
A12: i+l+1 <= len f by A11;
    i <= i+l by NAT_1:11;
    then 1 <= i+l by A10,XXREAL_0:2;
    then LE f/.(i+l), f/.(i+(l+1)), P, f/.1,f/.len f by A1,A12,Th23;
    hence thesis by A8,A10,A11,A9,Th13,XXREAL_0:2;
  end;
A13: ILE[0]
  proof
    assume 1 <= i & i+0 <= len f;
    then i in dom f by FINSEQ_3:25;
    hence thesis by A6,Th9,GOBOARD1:1;
  end;
A14: for l be Nat holds ILE[l] from NAT_1:sch 2(A13, A7);
  thus thesis by A2,A4,A5,A14;
end;
