
theorem :: theorem 3.1 (xii)
  for R, S being RelStr st R tolerates S & (the carrier of R) /\ (the
  carrier of S) is upper Subset of R & (the carrier of R) /\ (the carrier of S)
  is lower Subset of S & R is transitive antisymmetric & S is transitive
  antisymmetric holds R [*] S is antisymmetric
proof
  let R, S be RelStr;
  set X = the carrier of R [*] S, F = the InternalRel of R [*] S;
  assume that
A1: R tolerates S and
A2: (the carrier of R) /\ (the carrier of S) is upper Subset of R and
A3: (the carrier of R) /\ (the carrier of S) is lower Subset of S and
A4: R is transitive antisymmetric and
A5: S is transitive antisymmetric;
A6: the InternalRel of S is_antisymmetric_in the carrier of S by A5,
ORDERS_2:def 4;
A7: the InternalRel of R is_antisymmetric_in the carrier of R by A4,
ORDERS_2:def 4;
  F is_antisymmetric_in X
  proof
    let x, y be object;
    assume that
A8: x in X & y in X and
A9: [x,y] in F and
A10: [y,x] in F;
A11: x in (the carrier of R) \/ (the carrier of S) & y in (the carrier of
    R) \/ ( the carrier of S) by A8,Def2;
    per cases by A11,XBOOLE_0:def 3;
    suppose
A12:  x in the carrier of R & y in the carrier of R;
      then
      [x,y] in the InternalRel of R & [y,x] in the InternalRel of R by A1,A4,A9
,A10,Th4;
      hence thesis by A7,A12;
    end;
    suppose
A13:  x in the carrier of R & y in the carrier of S;
      then
A14:  y in the carrier of R by A3,A10,Th21;
      then
      [x,y] in the InternalRel of R & [y,x] in the InternalRel of R by A1,A4,A9
,A10,A13,Th4;
      hence thesis by A7,A13,A14;
    end;
    suppose
A15:  x in the carrier of S & y in the carrier of R;
      then
A16:  y in the carrier of S by A2,A9,Th17;
      then
      [x,y] in the InternalRel of S & [y,x] in the InternalRel of S by A1,A5,A9
,A10,A15,Th5;
      hence thesis by A6,A15,A16;
    end;
    suppose
A17:  x in the carrier of S & y in the carrier of S;
      then
      [x,y] in the InternalRel of S & [y,x] in the InternalRel of S by A1,A5,A9
,A10,Th5;
      hence thesis by A6,A17;
    end;
  end;
  hence thesis by ORDERS_2:def 4;
end;
