reserve x for set,
  C for Ordinal,
  L0 for Sequence;
reserve O1,O2 for Ordinal;

theorem Th24:
  for A being non empty set for L be lower-bounded LATTICE for d
being BiFunction of A,L for O1,O2 being Ordinal for q being QuadrSeq of d st O1
  c= O2 holds ConsecutiveDelta2(q,O1) c= ConsecutiveDelta2(q,O2)
proof
  let A be non empty set;
  let L be lower-bounded LATTICE;
  let d be BiFunction of A,L;
  let O1,O2 be Ordinal;
  let q be QuadrSeq of d;
  defpred X[Ordinal] means O1 c= $1 implies ConsecutiveDelta2(q,O1) c=
  ConsecutiveDelta2(q,$1);
A1: for O1 st O1 <> 0 & O1 is limit_ordinal & for O2 st O2 in O1 holds X[
  O2] holds X[O1]
  proof
    deffunc U(Ordinal) = ConsecutiveDelta2(q,$1);
    let O2 be Ordinal;
    assume that
A2: O2 <> 0 & O2 is limit_ordinal and
    for O3 be Ordinal st O3 in O2 holds O1 c= O3 implies ConsecutiveDelta2
    (q,O1) c= ConsecutiveDelta2(q,O3);
    consider L being Sequence such that
A3: dom L = O2 & for O3 being Ordinal st O3 in O2 holds L.O3 = U(O3)
    from ORDINAL2:sch 2;
A4: ConsecutiveDelta2(q,O2) = union rng L by A2,A3,Th20;
    assume
A5: O1 c= O2;
    per cases;
    suppose
      O1 = O2;
      hence thesis;
    end;
    suppose
      O1 <> O2;
      then
A6:   O1 c< O2 by A5;
      then O1 in O2 by ORDINAL1:11;
      then
A7:   L.O1 in rng L by A3,FUNCT_1:def 3;
      L.O1 = ConsecutiveDelta2(q,O1) by A3,A6,ORDINAL1:11;
      hence thesis by A4,A7,ZFMISC_1:74;
    end;
  end;
A8: for O1 being Ordinal st X[O1] holds X[succ O1]
  proof
    let O2 be Ordinal;
    assume
A9: O1 c= O2 implies ConsecutiveDelta2(q,O1) c= ConsecutiveDelta2(q,O2 );
    assume
A10: O1 c= succ O2;
    per cases;
    suppose
      O1 = succ O2;
      hence thesis;
    end;
    suppose
A11:  O1 <> succ O2;
      ConsecutiveDelta2(q,succ O2) = new_bi_fun2(BiFun(ConsecutiveDelta2(q
      ,O2), ConsecutiveSet2(A,O2),L),Quadr2(q,O2)) by Th19
        .= new_bi_fun2(ConsecutiveDelta2(q,O2),Quadr2(q,O2)) by LATTICE5:def 15
;
      then
A12:  ConsecutiveDelta2(q,O2) c= ConsecutiveDelta2(q,succ O2) by Th13;
      O1 c< succ O2 by A10,A11;
      then O1 in succ O2 by ORDINAL1:11;
      hence thesis by A9,A12,ORDINAL1:22;
    end;
  end;
A13: X[0];
  for O being Ordinal holds X[O] from ORDINAL2:sch 1(A13,A8,A1);
  hence thesis;
end;
