reserve r,r1,r2,g,g1,g2,x0,t for Real;
reserve n,k,m for Element of NAT;
reserve seq for Real_Sequence;
reserve f,f1,f2 for PartFunc of REAL,REAL;

theorem Th24:
  f1 is_divergent_to+infty_in x0 & (for r1,r2 st r1<x0 & x0<r2 ex
g1,g2 st r1<g1 & g1<x0 & g1 in dom f & g2<r2 & x0<g2 & g2 in dom f) & (ex r st
0<r & dom f /\ (].x0-r,x0.[ \/ ].x0,x0+r.[) c= dom f1 /\ (].x0-r,x0.[ \/ ].x0,
x0+r.[) & for g st g in dom f /\ (].x0-r,x0.[ \/ ].x0,x0+r.[) holds f1.g<=f.g)
  implies f is_divergent_to+infty_in x0
proof
  assume that
A1: f1 is_divergent_to+infty_in x0 and
A2: for r1,r2 st r1<x0 & x0<r2 ex g1,g2 st r1<g1 & g1<x0 & g1 in dom f &
  g2<r2 & x0<g2 & g2 in dom f;
  given r such that
A3: 0<r and
A4: dom f/\(].x0-r,x0.[\/].x0,x0+r.[)c=dom f1/\(].x0-r,x0.[\/ ].x0,x0+r .[) and
A5: for g st g in dom f/\(].x0-r,x0.[\/].x0,x0+r.[) holds f1.g<=f.g;
  thus for r1,r2 st r1<x0 & x0<r2 ex g1,g2 st r1<g1 & g1<x0 & g1 in dom f & g2
  <r2 & x0<g2 & g2 in dom f by A2;
  let s be Real_Sequence;
  assume that
A6: s is convergent and
A7: lim s=x0 and
A8: rng s c=dom f\{x0};
  consider k such that
A9: for n st k<=n holds x0-r<s.n & s.n<x0+r by A3,A6,A7,Th7;
A10: rng(s^\k)c= rng s by VALUED_0:21;
  then
A11: rng(s^\k)c=dom f\{x0} by A8;
  now
    let x be object;
    assume x in rng(s^\k);
    then consider n such that
A12: (s^\k).n=x by FUNCT_2:113;
A13: k<=n+k by NAT_1:12;
    then s.(n+k)<x0+r by A9;
    then
A14: (s^\k).n<x0+r by NAT_1:def 3;
    x0-r<s.(n+k) by A9,A13;
    then x0-r<(s^\k).n by NAT_1:def 3;
    then (s^\k).n in {g1: x0-r<g1 & g1<x0+r} by A14;
    then
A15: (s^\k).n in ].x0-r,x0+r .[ by RCOMP_1:def 2;
    (s^\k).n in rng(s^\k) by VALUED_0:28;
    then not (s^\k).n in {x0} by A11,XBOOLE_0:def 5;
    then (s^\k).n in ].x0-r,x0+r.[\{x0} by A15,XBOOLE_0:def 5;
    hence x in ].x0-r,x0.[\/].x0,x0+r.[ by A3,A12,Th4;
  end;
  then
A16: rng(s^\k)c=].x0-r,x0.[\/].x0,x0+r.[;
A17: rng s c=dom f by A8,XBOOLE_1:1;
  then rng(s^\k)c=dom f by A10;
  then
A18: rng(s^\k)c=dom f/\(].x0-r,x0.[\/].x0,x0+r.[) by A16,XBOOLE_1:19;
  then
A19: rng(s^\k)c=dom f1/\(].x0-r,x0.[\/].x0,x0+r.[) by A4;
A20: now
    let n be Nat;
A21:    n in NAT by ORDINAL1:def 12;
    (s^\k).n in rng(s^\k) by VALUED_0:28;
    then f1.((s^\k).n)<=f.((s^\k).n) by A5,A18;
    then (f1/*(s^\k)).n<=f.((s^\k).n) by A19,FUNCT_2:108,XBOOLE_1:18,A21;
    hence (f1/*(s^\k)).n<=(f/*(s^\k)).n
         by A17,A10,FUNCT_2:108,XBOOLE_1:1,A21;
  end;
A22: rng(s^\k)c=dom f1 by A19,XBOOLE_1:18;
  now
    let x be object;
    assume
A23: x in rng(s^\k);
    then not x in {x0} by A11,XBOOLE_0:def 5;
    hence x in dom f1\{x0} by A22,A23,XBOOLE_0:def 5;
  end;
  then
A24: rng(s^\k)c=dom f1\{x0};
  lim(s^\k)=x0 by A6,A7,SEQ_4:20;
  then f1/*(s^\k) is divergent_to+infty by A1,A6,A24;
  then f/*(s^\k) is divergent_to+infty by A20,LIMFUNC1:42;
  then (f/*s)^\k is divergent_to+infty by A8,VALUED_0:27,XBOOLE_1:1;
  hence thesis by LIMFUNC1:7;
end;
