reserve r,r1,r2,g,g1,g2,x0 for Real;
reserve f1,f2 for PartFunc of REAL,REAL;

theorem
  f1 is_right_convergent_in x0 & f2 is_right_divergent_to-infty_in
lim_right(f1,x0) & (for r st x0<r ex g st g<r & x0<g & g in dom(f2*f1)) & (ex g
  st 0<g & for r st r in dom f1 /\ ].x0,x0+g.[ holds lim_right(f1,x0)<f1.r)
  implies f2*f1 is_right_divergent_to-infty_in x0
proof
  assume that
A1: f1 is_right_convergent_in x0 and
A2: f2 is_right_divergent_to-infty_in lim_right(f1,x0) and
A3: for r st x0<r ex g st g<r & x0<g & g in dom(f2*f1);
  given g such that
A4: 0<g and
A5: for r st r in dom f1/\].x0,x0+g.[ holds lim_right(f1,x0)<f1.r;
  now
    let s be Real_Sequence;
    assume that
A6: s is convergent & lim s=x0 and
A7: rng s c=dom(f2*f1)/\right_open_halfline(x0);
    consider k be Nat such that
A8: for n be Nat st k<=n holds s.n<x0+g by A4,A6,Lm1,LIMFUNC2:2;
    set q=(f1/*s)^\k;
A9: rng s c=dom(f2*f1) by A7,Th1;
    rng(f1/*s)c=dom f2 by A7,Th1;
    then
A10: f2/*q=(f2/*(f1/*s))^\k by VALUED_0:27
      .=((f2*f1)/*s)^\k by A9,VALUED_0:31;
A11: rng s c=dom f1/\right_open_halfline(x0) by A7,Th1;
    then
A12: f1/*s is convergent by A1,A2,A6,LIMFUNC2:def 8;
A13: rng s c=dom f1 by A7,Th1;
A14: rng s c=right_open_halfline(x0) by A7,Th1;
    now
      let x be object;
      assume x in rng q;
      then consider n be Element of NAT such that
A15:  q.n=x by FUNCT_2:113;
A16:   n+k in NAT by ORDINAL1:def 12;
A17:  f1.(s.(n+k))=(f1/*s).(n+k) by A13,FUNCT_2:108,A16
        .=x by A15,NAT_1:def 3;
A18:  s.(n+k)<x0+g by A8,NAT_1:12;
A19:  s.(n+k) in rng s by VALUED_0:28;
      then s.(n+k) in right_open_halfline(x0) by A14;
      then s.(n+k) in {g1: x0<g1} by XXREAL_1:230;
      then ex g1 st g1=s.(n+k) & x0<g1;
      then s.(n+k) in {g2: x0<g2 & g2<x0+g} by A18;
      then s.(n+k) in ].x0,x0+g.[ by RCOMP_1:def 2;
      then s.(n+k) in dom f1/\].x0,x0+g.[ by A13,A19,XBOOLE_0:def 4;
      then lim_right(f1,x0)<f1.(s.(n+k)) by A5;
      then f1.(s.(n+k)) in {r1: lim_right(f1,x0)<r1};
      then
A20:  f1.(s.(n+k)) in right_open_halfline(lim_right(f1,x0)) by XXREAL_1:230;
      f1.(s.(n+k)) in dom f2 by A9,A19,FUNCT_1:11;
      hence x in dom f2/\right_open_halfline(lim_right(f1,x0)) by A20,A17,
XBOOLE_0:def 4;
    end;
    then
A21: rng q c=dom f2/\ right_open_halfline(lim_right(f1,x0));
    lim(f1/*s)=lim_right(f1,x0) by A1,A6,A11,LIMFUNC2:def 8;
    then lim q=lim_right(f1,x0) by A12,SEQ_4:20;
    then f2/*q is divergent_to-infty by A2,A12,A21,LIMFUNC2:def 6;
    hence (f2*f1)/*s is divergent_to-infty by A10,LIMFUNC1:7;
  end;
  hence thesis by A3,LIMFUNC2:def 6;
end;
