reserve X for set,
        n,m,k for Nat,
        K for Field,
        f for n-element real-valued FinSequence,
        M for Matrix of n,m,F_Real;

theorem Th24:
  for A be affinely-independent Subset of TOP-REAL n st the_rank_of M = n
  holds (Mx2Tran M).:A is affinely-independent
proof
  set MT=Mx2Tran M;
  set TRn=TOP-REAL n,TRm=TOP-REAL m;
  let A be affinely-independent Subset of TRn such that
   A1: the_rank_of M=n;
  per cases;
  suppose A is empty;
   then MT.:A is empty;
   hence thesis;
  end;
  suppose A is non empty;
   then consider v be Element of TRn such that
    A2: v in A and
    A3: (-v+A)\{0.TRn} is linearly-independent by RLAFFIN1:def 4;
    A4: dom MT=[#]TRn by FUNCT_2:def 1;
    then A5: MT.v in MT.:A by A2,FUNCT_1:def 6;
    MT.0.TRn=0.TRm by MATRTOP1:29;
    then A6: {0.TRm}=Im(MT,0.TRn) by A4,FUNCT_1:59
     .=MT.:{0.TRn} by RELAT_1:def 16;
    -v=0.TRn-v by RLVECT_1:14;
    then A7: MT.(-v)=(MT.(0.TRn))-(MT.v) by MATRTOP1:28
    .=(0.TRm)-(MT.v) by MATRTOP1:29
    .=-(MT.v) by RLVECT_1:14;
    MT is one-to-one by A1,MATRTOP1:39;
    then A8: MT.:((-v+A)\{0.TRn})=(MT.:(-v+A))\MT.:{0.TRn} by FUNCT_1:64
     .=(-(MT.v)+MT.:A)\{0.TRm} by A6,A7,MATRTOP1:30;
    MT.:((-v+A)\{0.TRn}) is linearly-independent by A1,A3,Th23;
    hence thesis by A5,A8,RLAFFIN1:def 4;
  end;
end;
