
theorem Th24:
for X be non empty set, S be SigmaField of X, M be sigma_Measure of S,
 f be PartFunc of X,ExtREAL, E be Element of S
  st E = dom f & f is nonnegative & f is E-measurable & Integral(M,f) = 0
  holds M.(E /\ great_dom(f,0)) = 0
proof
    let X be non empty set, S be SigmaField of X, M be sigma_Measure of S,
    f be PartFunc of X,ExtREAL, E be Element of S;
    assume that
A1:  E = dom f and
A2:  f is nonnegative and
A3:  f is E-measurable and
A4:  Integral(M,f) = 0;

    defpred P[Nat,object] means
     $2 = E /\ great_eq_dom(f,1/($1+1));

A5: for n be Element of NAT ex y be Element of S st P[n,y]
    proof
     let n be Element of NAT;
     E /\ great_eq_dom(f,1/(n+1)) is Element of S by A1,A3,MESFUNC1:27;
     hence thesis;
    end;

    consider F be Function of NAT,S such that
A6:  for n be Element of NAT holds P[n,F.n] from FUNCT_2:sch 3(A5);

A7: for n be Element of NAT holds (M*F).n = 0
    proof
     let n be Element of NAT;
     dom F = NAT by FUNCT_2:def 1; then
     (M*F).n = M.(F.n) by FUNCT_1:13
      .= M.(E /\ great_eq_dom(f,1/(n+1))) by A6;
     hence (M*F).n = 0 by A1,A2,A3,A4,Th23;
    end;

    rng F is N_Sub_set_fam of X & rng F c= S
      by MEASURE1:23,RELAT_1:def 19; then
    reconsider T = rng F as N_Measure_fam of S by MEASURE2:def 1;

    for n be Element of NAT holds F.n = E /\ great_eq_dom(f,(0+1/(n+1)))
      by A6; then
    E /\ great_dom(f,0) = union T by MESFUNC1:22; then
    M.(E /\ great_dom(f,0)) <= SUM(M*F) by MEASURE2:11; then
    M.(E /\ great_dom(f,0)) <= 0 by A7,MEASURE7:1;
    hence thesis by SUPINF_2:51;
end;
