reserve T, T1 for non empty TopSpace;
reserve F,G,H for Subset-Family of T,
  A,B,C,D for Subset of T,
  O,U for open Subset of T,
  p,q for Point of T,
  x,y,X for set;
reserve Un for FamilySequence of T,
  r,r1,r2 for Real,
  n for Element of NAT;

theorem Th24:
  for ADD being BinOp of Funcs(the carrier of T,REAL) st (for f1,
f2 being RealMap of T holds ADD.(f1,f2)=f1+f2) for map9 being Element of Funcs(
  the carrier of T,REAL) st map9 is_a_unity_wrt ADD holds map9 is continuous
proof
  let ADD be BinOp of Funcs(the carrier of T,REAL) such that
A1: for f1,f2 being RealMap of T holds ADD.(f1,f2)=f1+f2;
  set F=Funcs(the carrier of T,REAL);
  let map9 be Element of F such that
A2: map9 is_a_unity_wrt ADD;
A3: for x be Point of T holds map9.x=0
  proof
    assume ex x be Point of T st map9.x<>0;
    then consider x be Point of T such that
A4: map9.x<>0;
    ADD.(map9,map9)=map9 by A2,BINOP_1:3;
    then map9+map9=map9 by A1;
    then map9.x + map9.x = map9.x by Def7;
    hence thesis by A4;
  end;
  reconsider map99=map9 as Function of T,R^1 by TOPMETR:17;
  for A being Subset of T holds map99.:(Cl A) c= Cl(map99.:A qua Subset of R^1)
  proof
    let A be Subset of T;
    let mCla be object;
    assume mCla in map99.:(Cl A);
    then
A5: ex Cla being object st Cla in dom map9 & Cla in Cl A & mCla=map99.Cla by
FUNCT_1:def 6;
    then A <>{}T by PRE_TOPC:22;
    then consider a being object such that
A6: a in A by XBOOLE_0:def 1;
    reconsider a as Element of T by A6;
    dom map9=the carrier of T & map9.a =0 by A3,FUNCT_2:def 1;
    then 0 in map9.:A by A6,FUNCT_1:def 6;
    then
A7: mCla in map9.:A by A3,A5;
    map99.:A c= Cl(map99.:A) by PRE_TOPC:18;
    hence thesis by A7;
  end;
  then map99 is continuous by TOPS_2:45;
  hence thesis by JORDAN5A:27;
end;
