reserve D for set;
reserve x,x0,x1,x2,y,y0,y1,y2,z,z0,z1,z2,r,s,t for Real;
reserve p,a,u,u0 for Element of REAL 3;
reserve n,m,k for Element of NAT;
reserve f,f1,f2,f3,g for PartFunc of REAL 3,REAL;
reserve R,R1,R2 for RestFunc;
reserve L,L1,L2 for LinearFunc;

theorem
  f is_partial_differentiable`3_on D implies
  D c= dom f & for u st u in D holds f is_partial_differentiable_in u,3
proof
    assume
A1: f is_partial_differentiable`3_on D;
    hence D c= dom f;
    set g = f|D;
    let u0 be Element of REAL 3;
    assume u0 in D;then
 g is_partial_differentiable_in u0,3 by A1;
    then consider x0,y0,z0 being Real such that
A2: u0 = <*x0,y0,z0*> & ex N being Neighbourhood of z0
    st N c= dom SVF1(3,g,u0) & ex L,R st for z st z in N holds
    SVF1(3,g,u0).z - SVF1(3,g,u0).z0 = L.(z-z0) + R.(z-z0)
    by Th15;
    consider N being Neighbourhood of z0 such that
A3: N c= dom SVF1(3,g,u0) & ex L,R st for z st z in N holds
    SVF1(3,g,u0).z - SVF1(3,g,u0).z0 = L.(z-z0) + R.(z-z0) by A2;
    for z st z in dom (SVF1(3,g,u0)) holds z in dom (SVF1(3,f,u0))
    proof
      let z;
      assume z in dom (SVF1(3,g,u0));
  then
A4: z in dom reproj(3,u0) & reproj(3,u0).z in dom (f|D) by FUNCT_1:11;
      dom (f|D) = dom f /\ D by RELAT_1:61;then
      dom (f|D) c= dom f by XBOOLE_1:17;
      hence thesis by A4,FUNCT_1:11;
    end;
    then for z be object st z in dom (SVF1(3,g,u0))
          holds z in dom (SVF1(3,f,u0));
    then dom (SVF1(3,g,u0)) c= dom (SVF1(3,f,u0));then
A5: N c= dom (SVF1(3,f,u0)) by A3;
    consider L,R such that
A6: for z st z in N holds SVF1(3,g,u0).z - SVF1(3,g,u0).z0 =
      L.(z-z0) + R.(z-z0) by A3;
    for z st z in N holds SVF1(3,f,u0).z - SVF1(3,f,u0).z0 =
      L.(z-z0) + R.(z-z0)
    proof
      let z;
      assume
 A7: z in N;
 A8: for z st z in dom SVF1(3,g,u0) holds SVF1(3,g,u0).z = SVF1(3,f,u0).z
      proof
        let z;
        assume
   A9: z in dom (SVF1(3,g,u0));
   then
A10: z in dom reproj(3,u0) & reproj(3,u0).z in dom (f|D) by FUNCT_1:11;
        SVF1(3,g,u0).z = (f|D).(reproj(3,u0).z) by A9,FUNCT_1:12
        .= f.(reproj(3,u0).z) by A10,FUNCT_1:47
        .= SVF1(3,f,u0).z by A10,FUNCT_1:13;
        hence thesis;
      end;
 A11: z0 in N by RCOMP_1:16;
      L.(z-z0) + R.(z-z0) = SVF1(3,g,u0).z - SVF1(3,g,u0).z0 by A6,A7
      .= SVF1(3,f,u0).z - SVF1(3,g,u0).z0 by A3,A7,A8
      .= SVF1(3,f,u0).z - SVF1(3,f,u0).z0 by A3,A8,A11;
      hence thesis;
    end;
    hence thesis by A2,A5,Th15;
end;
