reserve n for Nat,
  a,b,c,d for Real,
  s for Real_Sequence;

theorem
  (for n st n>=1 holds s.n = 2|^n*((3*n-1)/4) & s.0=0) implies for n st
  n>=1 holds Partial_Sums(s).n = 2|^n*((3*n-4)/2)+2
proof
  defpred X[Nat] means Partial_Sums(s).$1=2|^$1*((3*$1-4)/2)+2;
  assume
A1: for n st n>=1 holds s.n = 2|^n*((3*n-1)/4) & s.0=0;
A2: for n be Nat st n>=1 & X[n] holds X[n+1]
  proof
    let n be Nat;
    assume that
    n>=1 and
A3: Partial_Sums(s).n =2|^n*((3*n-4)/2)+2;
A4: n+1>=1 by NAT_1:11;
    Partial_Sums(s).(n+1)=2|^n*((3*n-4)/2)+2+s.(n+1) by A3,SERIES_1:def 1
      .=(2|^n*((3*n-4)/2)+2)+(2|^(n+1)*((3*(n+1)-1)/4)) by A1,A4
      .=2|^n*((3*n-4)/2)+(2|^(n+1))*((3*n+2)/4)+2
      .=2|^n*((3*n-4)/2)+(2|^n*2)*((3*n+2)/4)+2 by NEWTON:6
      .=2|^n*2*((3*n-1)/2)+2
      .=2|^(n+1)*((3*(n+1)-4)/2)+2 by NEWTON:6;
    hence thesis;
  end;
  Partial_Sums(s).(1+0)=Partial_Sums(s).0+s.(1+0) by SERIES_1:def 1
    .= s.0 + s.1 by SERIES_1:def 1
    .=0+s.1 by A1
    .=2|^1*((3*1-1)/4) by A1
    .=2*(1/2)
    .=(3-4)/2*2+2
    .= (3-4)/2*2|^1+2
    .=2|^1*(3*1-4)/2+2;
  then
A5: X[1];
  for n be Nat st n>=1 holds X[n] from NAT_1:sch 8(A5,A2);
  hence thesis;
end;
