reserve X,Y,Z,Z1,Z2,D for set,x,y for object;
reserve SFX,SFY,SFZ for set;

theorem
  SFY <> {} implies X \/ meet SFY = meet UNION({X},SFY)
proof
  assume
A1: SFY <> {};
  set y = the Element of SFY;
  X in {X} by TARSKI:def 1;
  then
A2: X \/ y in UNION({X},SFY) by A1,Def4;
A3: X \/ meet SFY c= meet UNION({X},SFY)
  proof
    let x be object;
    assume x in X \/ meet SFY;
    then
A4: x in X or x in meet SFY by XBOOLE_0:def 3;
    for Z st Z in UNION({X},SFY) holds x in Z
    proof
      let Z;
      assume Z in UNION({X},SFY);
      then consider Z1,Z2 such that
A5:   Z1 in {X} & Z2 in SFY and
A6:   Z = Z1 \/ Z2 by Def4;
      x in Z1 or x in Z2 by A4,A5,Def1,TARSKI:def 1;
      hence thesis by A6,XBOOLE_0:def 3;
    end;
    hence thesis by A2,Def1;
  end;
  meet UNION({X},SFY) c= X \/ meet SFY
  proof
    let x be object;
    assume
A7: x in meet UNION({X},SFY);
    assume
A8: not x in X \/ meet SFY;
    then
A9: not x in X by XBOOLE_0:def 3;
    not x in meet SFY by A8,XBOOLE_0:def 3;
    then consider Z such that
A10: Z in SFY and
A11: not x in Z by A1,Def1;
    X in {X} by TARSKI:def 1;
    then X \/ Z in UNION({X},SFY) by A10,Def4;
    then x in X \/ Z by A7,Def1;
    hence contradiction by A9,A11,XBOOLE_0:def 3;
  end;
  hence thesis by A3;
end;
