reserve FS for non empty doubleLoopStr;
reserve F for Field;
reserve R for Abelian add-associative right_zeroed right_complementable non
  empty addLoopStr,
  x, y, z for Scalar of R;
reserve SF for Skew-Field,
  x, y, z for Scalar of SF;
reserve R, R1, R2 for Ring;

theorem Th24:
  for x,y being Scalar of R for v,w being Vector of RightModule R
  holds (v+w)*x = v*x+w*x & v*(x+y) = v*x+v*y & v*(y*x) = (v*y)*x & v*(1_R) = v
proof
  set MLT = the multF of R;
  set LS = RightModStr (# the carrier of R,the addF of R,0.R,MLT #);
  for x,y being Scalar of R for v,w being Vector of LS holds (v+w)*x = v*x
  +w*x & v*(x+y) = v*x+v*y & v*(y*x) = (v*y)*x & v*(1_R) = v
  proof
    let x,y be Scalar of R;
    let v,w be Vector of LS;
    reconsider v9 = v, w9 = w as Scalar of R;
    thus (v+w)*x = (v9+w9)*x .= v9*x+w9*x by VECTSP_1:def 7
      .= v*x+w*x;
    thus v*(x+y) = v9*(x+y) .= v9*x+v9*y by VECTSP_1:def 7
      .= v*x+v*y;
    thus v*(y*x) = v9*(y*x) .= (v9*y)*x by GROUP_1:def 3
      .= (v*y)*x;
    thus v*(1_R) = v9*(1_R) .= v;
  end;
  hence thesis;
end;
