reserve x,X,X2,Y,Y2 for set;
reserve GX for non empty TopSpace;
reserve A2,B2 for Subset of GX;
reserve B for Subset of GX;

theorem
  for A,B being Subset of GX st A is a_union_of_components of GX & B is
  a_union_of_components of GX holds A \ B is a_union_of_components of GX
proof
  let A,B be Subset of GX;
  assume that
A1: A is a_union_of_components of GX and
A2: B is a_union_of_components of GX;
  consider Fa being Subset-Family of GX such that
A3: for B2 being Subset of GX st B2 in Fa holds B2 is a_component and
A4: A=union Fa by A1,Def2;
  consider Fb being Subset-Family of GX such that
A5: for B3 being Subset of GX st B3 in Fb holds B3 is a_component and
A6: B=union Fb by A2,Def2;
  reconsider Fd=Fa\Fb as Subset-Family of GX;
A7: union Fd c= A \ B
  proof
    let x be object;
    assume x in union Fd;
    then consider X such that
A8: x in X and
A9: X in Fd by TARSKI:def 4;
    reconsider A2=X as Subset of GX by A9;
A10: not X in Fb by A9,XBOOLE_0:def 5;
A11: X in Fa by A9,XBOOLE_0:def 5;
    then
A12: A2 is a_component by A3;
A13: now
      assume x in B;
      then consider Y3 being set such that
A14:  x in Y3 and
A15:  Y3 in Fb by A6,TARSKI:def 4;
      reconsider B3=Y3 as Subset of GX by A15;
      A2 /\ B3 <>{} by A8,A14,XBOOLE_0:def 4;
      then
A16:  A2 meets B3;
      B3 is a_component by A5,A15;
      hence contradiction by A10,A12,A15,A16,CONNSP_1:35;
    end;
    A2 c= A by A4,A11,ZFMISC_1:74;
    hence thesis by A8,A13,XBOOLE_0:def 5;
  end;
A17: for B4 being Subset of GX st B4 in Fd holds B4 is a_component
  proof
    let B4 be Subset of GX;
    assume B4 in Fd;
    then B4 in Fa by XBOOLE_0:def 5;
    hence thesis by A3;
  end;
  A \ B c= union Fd
  proof
    let x be object;
    assume
A18: x in A \ B;
    then x in A by XBOOLE_0:def 5;
    then consider X such that
A19: x in X and
A20: X in Fa by A4,TARSKI:def 4;
    reconsider A2=X as Subset of GX by A20;
    now
      assume A2 in Fb;
      then A2 c= B by A6,ZFMISC_1:74;
      hence contradiction by A18,A19,XBOOLE_0:def 5;
    end;
    then A2 in Fd by A20,XBOOLE_0:def 5;
    hence thesis by A19,TARSKI:def 4;
  end;
  then A \ B=union Fd by A7;
  hence thesis by A17,Def2;
end;
