
theorem Th25:
  for X be non empty set for Y be ComplexNormSpace, f,g,h be Point
of C_NormSpace_of_BoundedFunctions(X,Y), f9,g9,h9 be bounded Function of X,the
  carrier of Y st f9=f & g9=g & h9=h holds (h = f-g iff for x be Element of X
  holds h9.x = f9.x - g9.x )
proof
  let X be non empty set;
  let Y be ComplexNormSpace;
  let f,g,h be Point of C_NormSpace_of_BoundedFunctions(X,Y);
  let f9,g9,h9 be bounded Function of X,the carrier of Y such that
A1: f9=f & g9=g & h9=h;
A2: now
    assume
A3: for x be Element of X holds h9.x = f9.x - g9.x;
    now
      let x be Element of X;
      h9.x = f9.x - g9.x by A3;
      then h9.x + g9.x= f9.x - (g9.x- g9.x) by RLVECT_1:29;
      then h9.x + g9.x= f9.x - 0.Y by RLVECT_1:15;
      hence h9.x + g9.x= f9.x by RLVECT_1:13;
    end;
    then f=h+g by A1,Th20;
    then f-g=h+(g-g) by RLVECT_1:def 3;
    then f-g=h+0.C_NormSpace_of_BoundedFunctions(X,Y) by RLVECT_1:15;
    hence f-g=h by RLVECT_1:4;
  end;
  now
    assume h=f-g;
    then h+g=f-(g-g) by RLVECT_1:29;
    then h+g=f-0.C_NormSpace_of_BoundedFunctions(X,Y) by RLVECT_1:15;
    then
A4: h+g=f by RLVECT_1:13;
    now
      let x be Element of X;
      f9.x=h9.x + g9.x by A1,A4,Th20;
      then f9.x-g9.x=h9.x + (g9.x-g9.x) by RLVECT_1:def 3;
      then f9.x-g9.x=h9.x + 0.Y by RLVECT_1:15;
      hence f9.x-g9.x=h9.x by RLVECT_1:4;
    end;
    hence for x be Element of X holds h9.x = f9.x - g9.x;
  end;
  hence thesis by A2;
end;
