 reserve n,m,i,p for Nat,
         h,k,r,r1,r2,x,x0,x1,x2,x3 for Real;
 reserve f,f1,f2,g for Function of REAL,REAL;

theorem
  x+h/2 in dom tan & x-h/2 in dom tan implies
  cD(tan(#)tan(#)cos,h).x = (tan(#)sin).(x+h/2)-(tan(#)sin).(x-h/2)
proof
  set f=tan(#)tan(#)cos;
  assume
A1:x+h/2 in dom tan & x-h/2 in dom tan;
  x+h/2 in dom f & x-h/2 in dom f
  proof
    set f1=tan(#)tan;
    set f2=cos;
A2: x+h/2 in dom f1 & x-h/2 in dom f1
    proof
      x+h/2 in dom tan /\ dom tan & x-h/2 in dom tan /\ dom tan by A1;
      hence thesis by VALUED_1:def 4;
    end;
    x+h/2 in dom f1 /\ dom f2 & x-h/2 in dom f1 /\ dom f2
                                        by A2,SIN_COS:24,XBOOLE_0:def 4;
    hence thesis by VALUED_1:def 4;
  end;
  then
  cD(f,h).x = (tan(#)tan(#)cos).(x+h/2)-(tan(#)tan(#)cos).(x-h/2) by DIFF_1:39
    .= (tan(#)tan).(x+h/2)*cos.(x+h/2)-(tan(#)tan(#)cos).(x-h/2) by VALUED_1:5
    .= tan.(x+h/2)*tan.(x+h/2)*cos.(x+h/2)-(tan(#)tan(#)cos).(x-h/2)
                                                                by VALUED_1:5
    .= tan.(x+h/2)*tan.(x+h/2)*cos.(x+h/2)-(tan(#)tan).(x-h/2)*cos.(x-h/2)
                                                             by VALUED_1:5
    .= tan.(x+h/2)*tan.(x+h/2)*cos.(x+h/2)-tan.(x-h/2)*tan.(x-h/2)*cos.(x-h/2)
                                                                  by VALUED_1:5
    .= (sin.(x+h/2)*(cos.(x+h/2))")*tan.(x+h/2)*cos.(x+h/2)
       -tan.(x-h/2)*tan.(x-h/2)*cos.(x-h/2) by A1,RFUNCT_1:def 1
    .= (sin.(x+h/2)*(cos.(x+h/2))"*tan.(x+h/2)*cos.(x+h/2))
       -(sin.(x-h/2)*(cos.(x-h/2))"*tan.(x-h/2)*cos.(x-h/2))
                                                   by A1,RFUNCT_1:def 1
    .= sin.(x+h/2)*tan.(x+h/2)*(cos.(x+h/2)*(1/cos.(x+h/2)))
       -sin.(x-h/2)*tan.(x-h/2)*(cos.(x-h/2)*(1/cos.(x-h/2)))
    .= sin.(x+h/2)*tan.(x+h/2)*1
       -sin.(x-h/2)*tan.(x-h/2)*(cos.(x-h/2)*(1/cos.(x-h/2)))
                                                 by A1,FDIFF_8:1,XCMPLX_1:106
    .= sin.(x+h/2)*tan.(x+h/2)*1-sin.(x-h/2)*tan.(x-h/2)*1
                                                 by A1,FDIFF_8:1,XCMPLX_1:106
    .= (tan(#)sin).(x+h/2)-tan.(x-h/2)*sin.(x-h/2) by VALUED_1:5
    .= (tan(#)sin).(x+h/2)-(tan(#)sin).(x-h/2) by VALUED_1:5;
  hence thesis;
end;
