 reserve o for object;
 reserve F for non almost_trivial Field;
 reserve x,a for Element of F;
reserve n for non zero Nat;

theorem Th20:
   for R being Ring, p being Polynomial of R for r being Rational holds p <> r
   proof
     let R be Ring, p be Polynomial of R; let r be Rational;
A1:  r in RAT+ \/ [:{0},RAT+:] \ {[0,0]} by NUMBERS:def 3,RAT_1:def 2;
     now assume
A2:    p = r; then
       not r in RAT+ by Lem2,Lem3; then
       r in [:{0},RAT+:] by A1,XBOOLE_0:def 3; then
       consider x,y being object such that
A3:    x in {0} & y in RAT+ & r = [x,y] by ZFMISC_1:def 2;
       dom p = NAT by FUNCT_2:def 1; then
       [1,p.1] in p by FUNCT_1:def 2; then
A4:    [1,p.1] in {{x,y},{x}} by A3,A2,TARSKI:def 5;
       per cases by A4,TARSKI:def 2;
       suppose [1,p.1] = {x,y}; then
A5:    {{1,p.1},{1}} = {x,y} by TARSKI:def 5;
A6:    x in {x,y} by TARSKI:def 2;
       per cases by A5,A6,TARSKI:def 2;
         suppose x = {1,p.1};
           hence contradiction by A3,TARSKI:def 1;
         end;
         suppose x = {1};
           hence contradiction by A3,TARSKI:def 1;
         end;
       end;
       suppose [1,p.1] = {x};
         hence contradiction by A3,TARSKI:def 1,CARD_1:49;
       end;
     end;
     hence thesis;
   end;
