reserve Omega for non empty set;
reserve Sigma for SigmaField of Omega;
reserve S for non empty Subset of REAL;
reserve r for Real;
reserve T for Nat;
reserve I for TheEvent of r;

theorem
for MyFunc being Filtration of S,Sigma,
    k1,k2 be StoppingTime_Func of Sigma,MyFunc
     st k1<=k2 holds
      Sigma_tau(MyFunc,k1) c= Sigma_tau(MyFunc,k2)
proof
 let MyFunc be Filtration of S,Sigma;
 let k1,k2 be StoppingTime_Func of Sigma,MyFunc;
 assume ASS0: k1<=k2;
   let x be object;
   assume x in Sigma_tau(MyFunc,k1); then
   consider A being Element of Sigma such that
Z1:x=A & for t being Element of S holds
     A /\ {w2 where w2 is Element of Omega: k1.w2<=t} in MyFunc.t;
   reconsider x as Element of Sigma by Z1;
   for t being Element of S holds
     x /\ {w2 where w2 is Element of Omega: k2.w2<=t} in MyFunc.t
     proof
      let t be Element of S;
      reconsider MyFt = MyFunc.t as SigmaField of Omega by KOLMOG01:def 2;
        set Imp0={w2 where w2 is Element of Omega: k2.w2<=t};
        set Imp1=x /\ Imp0;
        set Imp2=x /\ {w2 where w2 is Element of Omega: k1.w2<=t} /\ Imp0;
BU2:    x /\ {w where w is Element of Omega: k1.w<=t} is Event of MyFt by Z1;
    P1: Imp1 = Imp2
        proof
         thus Imp1 c= Imp2
         proof
          let y be object;
          assume zw1: y in Imp1; then
     ZW1: y in x & y in {w where w is Element of Omega: k2.w<=t}
            by XBOOLE_0:def 4; then
          consider w2 being Element of Omega such that
     ZW2: y=w2 & k2.w2<=t;
          k1.w2<=k2.w2 & k2.w2<=t by ZW2,ASS0; then
          k1.w2<=t by XXREAL_0:2; then
          y in x & y in {w where w is Element of Omega: k1.w<=t}
            by ZW2,zw1,XBOOLE_0:def 4;
          then y in (x /\ {w where w is Element of Omega: k1.w<=t})
            by XBOOLE_0:def 4;
          hence thesis by ZW1,XBOOLE_0:def 4;
         end;
         let y be object;
         assume y in Imp2;
         then y in x /\ {w where w is Element of Omega: k1.w<=t} & y in
           Imp0 by XBOOLE_0:def 4; then
         y in x & y in {w where w is Element of Omega: k1.w<=t} & y in
           {w where w is Element of Omega: k2.w<=t} by XBOOLE_0:def 4;
         hence thesis by XBOOLE_0:def 4;
        end;
       Imp1 is Event of MyFt
       proof
        k2 is_StoppingTime_wrt MyFunc,S by Def11111; then
        {w where w is Element of Omega: k2.w<=t} is Event of MyFt;
        hence thesis by P1,BU2,PROB_1:19;
       end;
     hence thesis;
   end;
  hence thesis;
end;
