reserve E, x, y, X for set;
reserve A, B, C for Subset of E^omega;
reserve a, b for Element of E^omega;
reserve i, k, l, kl, m, n, mn for Nat;

theorem Th25:
  m <= k & k <= n implies A |^ (m, n) = A |^ (m, k) \/ A |^ (k + 1 , n)
proof
  assume that
A1: m <= k and
A2: k <= n;
  per cases;
  suppose
A3: k < n;
    m <= k + 1 by A1,NAT_1:13;
    then
A4: A |^ (k + 1, n) c= A |^ (m, n) by Th23;
A5: A |^ (m, n) c= A |^ (m, k) \/ A |^ (k + 1, n)
    proof
      let x be object;
      assume x in A |^ (m, n);
      then consider mn such that
A6:   m <= mn and
A7:   mn <= n and
A8:   x in A |^ mn by Th19;
A9:   mn >= k + 1 implies x in A |^ (k + 1, n) by A7,A8,Th19;
      mn <= k implies x in A |^ (m, k) by A6,A8,Th19;
      hence thesis by A9,NAT_1:13,XBOOLE_0:def 3;
    end;
    A |^ (m, k) c= A |^ (m, n) by A3,Th23;
    then A |^ (m, k) \/ A |^ (k + 1, n) c= A |^ (m, n) by A4,XBOOLE_1:8;
    hence thesis by A5,XBOOLE_0:def 10;
  end;
  suppose
A10: k >= n;
    then k + 1 > n + 0 by XREAL_1:8;
    then A |^ (k + 1, n) = {} by Th21;
    hence thesis by A2,A10,XXREAL_0:1;
  end;
end;
