
theorem Th25:
  for G1 being _Graph, v0, v1 being Vertex of G1
  for G2 being removeVertex of G1,v0, v2 being Vertex of G2
  st v0 is endvertex & v1 = v2 & v1 in G1.reachableFrom(v0)
  holds G2.reachableFrom(v2) = G1.reachableFrom(v1) \ {v0}
proof
  let G1 be _Graph, v0,v1 be Vertex of G1;
  let G2 be removeVertex of G1, v0, v2 be Vertex of G2;
  assume A1: v0 is endvertex & v1 = v2 & v1 in G1.reachableFrom(v0);
  then A2: G1 is non _trivial by GLIB_000:122;
  then A3: the_Vertices_of G2 = the_Vertices_of G1 \ {v0} by GLIB_000:47;
  for w being object holds w in G2.reachableFrom(v2) iff
    w in G1.reachableFrom(v1) & not w in {v0}
  proof
    let w be object;
    thus w in G2.reachableFrom(v2) implies w in G1.reachableFrom(v1) &
      not w in {v0} by A1, A3, GLIB_002:14, TARSKI:def 3, XBOOLE_0:def 5;
    assume A4: w in G1.reachableFrom(v1) & not w in {v0};
    then consider W being Walk of G1 such that
      A5: W is_Walk_from v1, w by GLIB_002:def 5;
    set P = the Path of W;
    v1 is set & w is set by TARSKI:1;
    then A6: P is_Walk_from v1, w by A5, GLIB_001:160;
    not v0 in P.vertices()
    proof
      assume v0 in P.vertices();
      then per cases by A1, GLIB_001:143;
      suppose v0 = P.first();
        then v0 = v2 by A1, A6, GLIB_001:def 23;
        then not v0 in {v0} by A3, XBOOLE_0:def 5;
        hence contradiction by TARSKI:def 1;
      end;
      suppose v0 = P.last();
        then v0 = w by A6, GLIB_001:def 23;
        hence contradiction by A4, TARSKI:def 1;
      end;
    end;
    then reconsider P as Walk of G2 by A2, GLIB_001:171;
    P is_Walk_from v2, w by A1, A6, GLIB_001:19;
    hence w in G2.reachableFrom(v2) by GLIB_002:def 5;
  end;
  hence thesis by XBOOLE_0:def 5;
end;
